☰

使用 awk 和 gsub 根据另一列修改特定列

tag-icon • tag-icon bash xubuntu windows-subsystem-for-linux linux-headers
使用 awk 和 gsub 根据另一列修改特定列

我有一个包含数百万行和列的文件 (file1)。数据示例如下：

"col1","col2","col3","col4","col5","col6"
"AAA",0,5,10,"BGB",50
"BBB",4,7,10,"BFD",76
"AAA",15,0,0,"BGB",20
"AAA",10,13,10,"DDD",23

我想找到 col1 中所有包含 AAA 的行，然后获取 col5 中所有包含 BGB 的行。最后，将 col2、col3、col4 和 col6 中的每个值减少 50%（如果单元格值为 0 或空白，则忽略）。然后打印文件的所有行。因此，我的输出将如下所示：

"col1","col2","col3","col4","col5","col6"
"AAA",0,2.5,5,"BGB",25
"BBB",4,7,10,"BFD",76
"AAA",7.5,0,0,"BGB",10
"AAA",10,13,10,"DDD",23

我一直在尝试以下操作，但无法使其工作（也无法弄清楚如何在 gsub 中使用多列）

grep AAA file1 | awk -F "," '$5~/BGB/ {gsub($6,\substr($6,1,length($6)-1)*0.50\, $6}1'

答案1

awk 可以像 grep 一样匹配模式，因此您几乎不需要在管道中使用 grep 和 awk。

你可以做

 awk  '
    BEGIN {FS = OFS = ","}
    $1 ~ /AAA/ && $5 ~ /BGB/ {
        if ($2) $2 = $2 / 2
        if ($3) $3 = $3 / 2
        if ($4) $4 = $4 / 2
        if ($6) $6 = $6 / 2
    }
    1
' file

或者，如果你想让列减少得更加动态

awk -v "columns=2,3,4,6" '
    BEGIN {
        FS = OFS = ","
        n = split(columns, a, /,/)
        for (i=1; i<=n; i++) cols[a[i]]=1
    }
    $1 ~ /AAA/ && $5 ~ /BGB/ {
        for (c in cols) if ($c) $c = $c / 2
    }
    1
' file

相关内容