☰

sed 计算模式之间的行数 - 多个文件

tag-icon • tag-icon bash text-processing sed pipe wc
sed 计算模式之间的行数 - 多个文件

我.txt在一个目录中有多个文件。每个文件都有一个部分：

DONE
item 1
item 2
item 3
DONE

我想DONE分别计算每个文件的两个标记之间的行数。

我用了这个问题创建这个：

sed -n "/DONE/,/DONE/ p" *.txt | wc -l > ~/word_count.txt

但这会将每个文件的计数合并为一个数字。相反，我想要这样的输出：

file1.txt 3
file2.txt 5
file3.txt 6

答案1

更好地awk使用数数。

awk '
  FNR == 1 {inside = 0}
  $0 == "DONE" {
    if (inside) print FILENAME, n
    n = 0
    inside = ! inside
    next
  }
  inside {n++}' ./*.txt

这将为DONE...DONE每个文件中的每个部分打印一条记录，这意味着如果没有这样的部分，则不会打印任何内容。要打印0这些内容，您需要 GNU 实现awk及其BEGINFILE特殊ENDFILE语句：

awk '
  BEGINFILE {DONE_count = 0}
  $0 == "DONE" {
    if (++DONE_count % 2 == 0) print FILENAME, n
    n = 0
    next
  }
  DONE_count % 2 {n++}
  ENDFILE {if (!DONE_count) print FILENAME, 0}' ./*.txt

awk或者每个文件运行一个：

for file in ./*.txt; do
  awk '
    $0 == "DONE" {
      if (++DONE_count % 2 == 0) print FILENAME, n
      n = 0
      next
    }
    DONE_count % 2 {n++}
    END {if (!DONE_count) print FILENAME, 0}' "$file"
done

答案2

perl -lne '
   eof and !$a && print "$ARGV: ", 0+$a;          # no DONEs => ans=0
   next unless /DONE/ && !$a ... /DONE/;          # skip non-DONE ranges
   /DONE/ and !$a++ && next;                      # begin DONE range
   !/DONE/ and !eof and $a++,next;                # middle of DONE range
   !/DONE/ and eof and $a=2;                      # lone DONE => ans=0
   print "$ARGV: ", ($a-2, $a=0, close ARGV)[0];  # end of DONE range
                                                  # at the end we do 4 things: 1) subtract 2 from sum, 2) print filename+sum, 3) reset sum, and 4) skip the current file and jump to the next file in queue.
' ./*.txt

我们sed可以在每个文件的基础上执行此操作：

for f in ./*.txt; do
   printf '%s: %d\n' "$f" "$(sed -e '/DONE/,/DONE/!d; //d' "$f" | wc -l)"
done

不同之处在于我们不会完成结账的情况。

相关内容