☰

如何将连续数字折叠成范围？

tag-icon • tag-icon text-processing awk perl numeric-data
如何将连续数字折叠成范围？

给定一个包含唯一数字（每行一个）的排序输入文件（或命令输出），我想将连续数字的所有运行折叠到范围中，以便

n
n+1
...
n+m

变成

n,n+m

输入样本：

2
3
9
10
11
12
24
28
29
33

预期输出：

2,3
9,12
24
28,29
33

答案1

进行dc心理锻炼：

dc -f "$1" -e '
[ q ]sB
z d 0 =B sc sa z sb
[ Sa lb 1 - d sb 0 <Z ]sZ
lZx
[ 1 sk lf 1 =O lk 1 =M ]sS
[ li p c 0 d sk sf ]sO
[ 2 sf lh d sj li 1 + !=O ]sQ
[ li n [,] n lj p c 0 sf ]sM
[ 0 sk lh sj ]sN
[ 1 sk lj lh 1 - =N lk 1 =M ]sR
[ 1 sf lh si ]sP
[ La sh lc 1 - sc lf 2 =R lf 1 =Q lf 0 =P lc 0 !=A ]sA
lAx
lSx
'

答案2

awk '
    function output() { print start (prev == start ? "" : ","prev) }
    NR == 1 {start = prev = $1; next}
    $1 > prev+1 {output(); start = $1}
    {prev = $1}
    END {output()}
'

答案3

awk，采用不同的（更像C）方法：

awk '{ do{ for(s=e=$1; (r=getline)>0 && $1<=e+1; e=$1); print s==e ? s : s","e }while(r>0) }' file

同样的事情，甚至更不尴尬：

awk 'BEGIN{
    for(r=getline; r>0;){
        for(s=e=$1; (r=getline)>0 && $1<=e+1; e=$1);
        print s==e ? s : s","e
    }
    exit -r
}' file

答案4

另一种awk方法（一种变体格伦的回答）：

awk '
    function output() { print start (start != end? ","end : "") }
    end==$0-1 || end==$0 { end=$0; next }
    end!=""{ output() }
    { start=end=$0 }
END{ output() }' infile

相关内容