☰

empathy-log.xsl 在哪里？

tag-icon • tag-icon chat empathy xslt
empathy-log.xsl 在哪里？

Empathy 保存的对话日志采用 XML 格式。每个日志都链接到样式表“empathy-log.xsl”：

<?xml-stylesheet type="text/xsl" href="empathy-log.xsl"?>

我搜索了我的硬盘和网络，但找不到它（有一个 empathy-log-manager.xsl，但这个不一样）。它存在吗？如果没有这样的文件，我会自己创建，但我宁愿使用提供的文件。

答案1

我也找不到同理心日志.xsl所以我自己写了。对于无法这样做的人，我在这里提供我的：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" omit-xml-declaration="yes" /> 
<xsl:template match="/">
 <html>
 <head>
 <style type="text/css">
 ul { list-style-type:none; padding:0; }
 li { border:0.15em solid #ddd; margin-bottom:0.6em; padding:0.3em 0.3em 0 0.3em; background-color:#ffc; font-size:smaller; font-weight:bold; }
 div { font-size:larger; font-weight:normal; border-top:0.1em solid #8F8FFF; padding:0.3em; }
 </style>
 </head>
 <body>
 <ul>
  <xsl:for-each select="log/message[position()=1 or @name != preceding-sibling::message[1]/@name]">
   <li>
    <xsl:value-of select="@name"/>
    <div><xsl:value-of select="."/></div>
    <xsl:call-template name="nextText" />
   </li>
  </xsl:for-each>
 </ul>
 </body>
 </html>
</xsl:template>

<xsl:template name="nextText">
 <xsl:if test="@name = following-sibling::message[1]/@name">
  <xsl:for-each select="following-sibling::message[1]">
   <div><xsl:value-of select="."/></div>
   <xsl:call-template name="nextText"/>
  </xsl:for-each>
 </xsl:if>
</xsl:template>
</xsl:stylesheet>

将此代码复制到文件中同理心日志.xsl在与日志文件相同的文件夹中，并将日志文件重命名为 .xml 文件。现在在浏览器中打开该文件。

答案2

您可以使用locate命令来获取文件的路径：

$ locate empathy-log.xsl

只是为了确保在使用locate之前你应该更新文件数据库：

$ sudo updatedb

相关内容