☰

Windows 资源管理器的自定义多项上下文菜单条目

tag-icon • tag-icon windows windows-explorer shell-script context-menu desktop-customization
Windows 资源管理器的自定义多项上下文菜单条目

我正在尝试为 Windows (7) Explorer 创建一个自定义上下文菜单项，它将向一个单一命令发送所有选定的项目。

我MultiSelectModel读过玩家价值MSDN 文档但这似乎不起作用。这就是我尝试过的：

  1. 在 HKEY_CLASSES_ROOT/*/shell 下创建了键“MYVERB”
    1. （默认）'myverb' 是 'my verb'
  2. 在“MYVERB”下创建了键“COMMAND”
    1. （默认）'command' 为 'python C:\MyScript.py "%1" "%2" "%3" "%4" "%5"'

这对于一个项目来说很有效。

但是当选择了许多项目时，脚本会为每个项目启动一次。相反，我希望只有一个实例来接收所有选定的项目。

我尝试在“MYVERB”和“COMMAND”下添加字符串值“MultiSelectModel”->“Player”，但行为没有改变。

我尝试仅使用脚本和注册表就可以完成操作吗？我做错了什么？

答案1

以下是一个例子：

HKLM\SOFTWARE\Classes\SystemFileAssociations.bmp\Shell\setdesktopwallpaper\MultiSelectModel

%使用 Player 时无需指定任何参数，只需指定命令本身。

您可能想尝试使用将命令行打印到文件的脚本，以便了解幕后发生的事情。但我认为在这种情况下，"%1" 等等的规范破坏了它……

答案2

这是 Chrome 打开多个文件的一种解决方法。

用您的程序和注册表项替换 chrome.exe 路径，或者您可以保留注册表项不变。

概括

  1. 在注册表中将目标程序设置为上下文菜单创建文件.exe写道注册表文件文件。

  2. 在主程序中每 1 秒循环检查一次注册表文件存在。如果存在，则终止上下文菜单创建文件.exe并删除注册表文件文件。然后复制选定的文件路径并对其进行操作。

  3. 如果你的程序循环检查注册表文件，那么您需要在启动时或手动执行上下文菜单之前启动该程序。

我这样做了自动热键。

下面这两个 AutoHotkey 脚本允许您在 Windows 资源管理器中添加Open With Chrome上下文菜单项以打开多个选定的文件。

您可以保留所有变量值，但如果您想更改值contextMenu和program名称，请参阅3.1.

指示：

在同一目录中创建2个文件：

  1. 创建第一个程序添加到上下文菜单并创建启动快捷方式.ahk

    1. RunAsAdmin标签确保脚本以管理员身份运行（修复添加注册表值）。

      1. 检查If (!A_IsAdmin)当前用户是否不是admin，A_IsAdmin 是内置的 AutoHotkey 变量，如果用户是管理员则返回 1，否则返回 0。
      2. Run, \*RunAs "%A_ScriptFullPath%" *运行方式参数以管理员身份运行脚本，“%A_ScriptFullPath%”获取当前执行脚本的完整路径。
      3. ExitApp退出当前以非管理员权限运行的脚本实例。
      4. 因为该Run命令以管理员权限再次运行脚本，所以它将跳过IF条件并继续执行下面的代码。

    2. ContextMenuCreateFile:标签创建上下文菜单创建文件.exe创建一个文件注册表文件并退出上下文菜单创建文件.exe写入文件后注册表文件. 确保在命令Ahk2Exe.exe中指定路径的位置RunWait。

    3. Add To Context Menu:标签添加运行的注册表项上下文菜单创建文件.exe。

      1. 将变量设置contextMenu为需要在上下文菜单中显示的内容。（名称program设置为contextMenu）
      2. 设置regPath为您想要的注册表路径。
      3. 当它执行时MsgBox，检查命令是否添加到地址栏中的注册表中。

    4. CreateStartupShortcut:Label创建主程序的快捷方式使用 Chrome.exe 打开在启动文件夹中。

添加到上下文菜单并创建启动快捷方式.ahk

; =============Recommended Settings=============
#NoEnv
SetWorkingDir %A_ScriptDir%
#Warn
CoordMode, Mouse, Window
SendMode Input
#SingleInstance Force
SetTitleMatchMode 2
SetTitleMatchMode Fast
DetectHiddenWindows Off
DetectHiddenText On
#WinActivateForce
#NoTrayIcon
SetControlDelay 1
SetWinDelay 0
SetKeyDelay -1
SetMouseDelay -1
SetBatchLines -1
#Persistent
#MaxThreadsPerHotkey 2
; =============Recommended Settings=============

AddToContextMenuAndCreateStartupShortcut:
RunAsAdmin:  ; =============RunAsAdmin=============
If (!A_IsAdmin)  ; IF NOT Admin
{
    Run, *RunAs "%A_ScriptFullPath%"  ; Run script as admin
    ExitApp  ; Exit the current instance running without admin privileges
}
ContextMenuCreateFile:  ; =============ContextMenuCreateFile=============
contextMenuCreateFileAhk := 
(LTrim
"#NoEnv
#NoTrayIcon
#SingleInstance Force
SetWorkingDir %A_ScriptDir%
SetBatchLines -1

ContextMenuCreateFile:
FileDelete, reg.txt
FileAppend, , reg.txt
ExitApp
Return"
)  ; contextMenuCreateFileAhk
FileDelete, Context Menu Create File.exe  ; DEL Context Menu Create File.exe
FileDelete, Context Menu Create File.ahk  ; DEL Context Menu Create File.ahk
FileAppend, %contextMenuCreateFileAhk%, Context Menu Create File.ahk  ; MAKE Context Menu Create File.ahk
RunWait, C:\Program Files\AutoHotkey\Compiler\Ahk2Exe.exe /in "Context Menu Create File.ahk" /out "Context Menu Create File.exe"  ; Convert AHK to EXE
FileDelete, Context Menu Create File.ahk  ; DEL Context Menu Create File.ahk
AddToContextMenu:  ; =============AddToContextMenu=============
path := ""  ; path
program := "Context Menu Create File"  ; program
contextMenu := "Open With Chrome"  ; contextMenu
regPath := "HKCR\*\shell"  ; regPath
StringReplace, regKey, contextMenu, %A_Space%, , A  ; regKey
regKey := 0 regKey  ; regKey
Loop, Files, %program%.exe, F  ; Find Program.exe In Current Dir
{
    path := A_LoopFileLongPath  ; Set Program Path
}
cmd := 
(LTrim
"reg add """ regPath "\" regKey """ /ve /t REG_SZ /d """ contextMenu """ /f
reg add """ regPath "\" regKey "\command"" /ve /t REG_SZ /d ""\""" path "\""`"" /f"
)  ; Registry
FileDelete, Add To Context Menu.bat  ; CREATE Add To Context Menu.bat
FileAppend, %cmd%, Add To Context Menu.bat  ; CREATE Add To Context Menu.bat
RunWait, Add To Context Menu.bat, , Hide  ; RUN Add To Context Menu.bat (*RunAs ADMIN)
FileDelete, Add To Context Menu.bat  ; DEL Add To Context Menu.bat
Run, regedit  ; regedit
WinWait, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; Registry
Sleep, 333
ControlSetText, Edit1, %regPath%\%regKey%\command, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; regPath
ControlFocus, Edit1, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; regPath
ControlSend, Edit1, {Enter}, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; regPath
ControlSend, SysListView321, {Control Down}{NumpadAdd}{Control Up}, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; regPath
ControlSend, SysListView321, {F5}, Registry Editor ahk_class RegEdit_RegEdit ahk_exe regedit.exe  ; regPath
MsgBox, 262192, CHECK, Check If Added %contextMenu% To Registry  ; CHECK
CreateStartupShortcut:  ; =============CreateStartupShortcut=============
path := ""  ; path
program := contextMenu  ; program
Loop, Files, %program%.exe, F  ; Find Program.exe In Current Dir
{
    path := A_LoopFileLongPath  ; Set Program Path
}
FileCreateShortcut, %path%, %A_Startup%\%program%.lnk  ; Create Startup Shortcut
Run, %A_Startup%, , Max  ; Check If Shortcut Created
Run, "%program%.exe"  ; Run Program
MsgBox, 262144, CHECK, Check If Shortcut Created  ; CHECK
ExitApp  ; ExitApp
Return
  1. 创建第二个程序使用 Chrome.ahk 打开这是主程序。
    1. 这里Loop创建了一个 a，并每隔 1 秒检查一次注册表文件存在。
    2. IfExist, reg.txt它杀死了上下文菜单创建文件.exe并删除注册表文件。
    3. 然后它激活 explorer.exe 窗口并将所有选定的文件路径复制到剪贴板。
    4. If CLIPBOARD contains .,\确保;确定剪贴板包含路径“\”带延伸“。”。
    5. 选定文件的列表保存在selectedFiles变量中。
    6. 下面的循环chromeParams := ""循环遍历选定的文件，获取filePaths 并用双引号将其括起来，并将StringReplaceWindows 路径替换为 url 文件路径（例如：C:\path\file.jpgto）file:///path/file.jpg。
    7. 然后将filePath连接到chromeParams。
    8. StringTrimRight从字符串中删除最后一个空格chromeParams。
    9. 然后Run, chrome.exe %chromeParams%使用（选定文件列表）执行%chromeParams%。（如果该命令未打开 Chrome，则输入 Chrome 的完整路径，例如：Run, C:\Program Files (x86)\Google\Chrome\Application\chrome.exe使用相同的参数）

使用 Chrome.ahk 打开

; =============Recommended Settings=============
#NoEnv
SetWorkingDir %A_ScriptDir%
#Warn
CoordMode, Mouse, Window
SendMode Input
#SingleInstance Force
SetTitleMatchMode 2
SetTitleMatchMode Fast
DetectHiddenWindows Off
DetectHiddenText On
#WinActivateForce
#NoTrayIcon
SetControlDelay 1
SetWinDelay 0
SetKeyDelay -1
SetMouseDelay -1
SetBatchLines -1
#Persistent
#MaxThreadsPerHotkey 2
; =============Recommended Settings=============

OpenWithChrome:
Loop  ; Loop Start
{
    Sleep, 1000  ; Fix High CPU
    IfExist, reg.txt  ; IF reg.txt EXIST
    {
        RunWait, cmd /c taskkill /im "Context Menu Create File.exe" /f, , Hide  ; Fix Opening 2 Compose Windows
        FileDelete, reg.txt  ; DEL reg.txt
        WinActivate, ahk_class CabinetWClass ahk_exe explorer.exe  ; Explorer
        CLIPBOARD := ""  ; Clear Clipboard
        Send, {Control Down}{c}{Control Up}  ; Copy File Paths
        ClipWait, 0  ; Clip Wait
        If CLIPBOARD contains .,\  ; IF CLIPBOARD contains .,\
        {
            selectedFiles := CLIPBOARD  ; selectedFiles
            chromeParams := ""  ; chromeParams
            Loop, Parse, selectedFiles, `n, `r  ; Loop Start selectedFiles
            {
                filePath := """file:///" A_LoopField """"  ; filePath
                StringReplace, filePath, filePath, \, /, A  ; Replace \ with /
                chromeParams .= filePath . " "  ; chromeParams .= %filePath%,
            }
            StringTrimRight, chromeParams, chromeParams, 1  ; Remove Last Space
            Run, chrome.exe %chromeParams%  ; Open Files In Chrome
        }
    }
}
Return

  1. 转换两者添加到上下文菜单并创建启动快捷方式.ahk和使用 Chrome.ahk 打开到EXE文件使用同一目录中的文件Ahk2Exe 工具-->（在开始菜单中找到，只需浏览文件并点击转换）

  2. 执行Add To Context Menu And Create Startup Shortcut.exe

  3. 选择文件，右键单击，然后使用 Chrome 打开应该出现上下文菜单项。

相关内容