☰

ZSH：历史搜索的菜单选择自动完成

tag-icon • tag-icon zsh
ZSH：历史搜索的菜单选择自动完成

ZSH 具有强大的菜单选择自动完成功能，例如选择目录、使用 kill (kill[tab][tab]) 选择进程。您可以使用箭头在选项之间导航。

是否也可以弹出历史搜索 (CTRL+R) 菜单？这样菜单就可以浏览当前 CTRL+R 搜索栏的匹配项？

答案1

我知道这与您的要求相差甚远，但它可能会解决您的根本问题。

有一个 shell 历史记录扩展，可在搜索历史记录时向您显示一页完整的结果。它还会根据当前目录、git 存储库、退出状态和主机首先向您显示相关结果。

您可以在此处安装该项目：https://github.com/curusarn/resh
CTRL使用+ 启动它R（替代反向搜索）。
搜索应用程序如下所示：

搜索应用程序的屏幕截图

免责声明：我是该项目的创建者，这是无耻的自我宣传

答案2

zsh-navigation-tools类似这样的操作。如果您使用 oh-my-zsh，则只需在您的ctrl-R 中zsh-navigation-tools添加即可，然后 ctrl-R 将为您提供带有向上/向下和搜索/过滤的滚动历史记录。您可以在没有 oh-my-zsh 的情况下使用它，但设置看起来需要更多工作。plugins=(...).zshrc

答案3

  1. 从来没听说过。

  2. 也许您希望尝试predict-on，它会做一些与您的要求相关的事：

    autoload -U predict-on
zle -N predict-on
zle -N predict-off
bindkey '^X1' predict-on
bindkey '^X2' predict-off

答案4

这是可能的；原则上，我修改了_kill完成部分，使其也适用于历史事件。

以下是示例；选择条目后，按一次 [ENTER] 接受事件编号（命令行显示为 fe hc 780），然后再次按 [ENTER] 执行命令。（如果您想在执行之前修改命令行，请使用fc而不是）。hc

$ hc Makefile[TAB]
history event
 1906  9.3.2013 18:10  vi Makefile
 1867  9.3.2013 17:26  less Makefile
  780  3.2.2013 17:54  cat Makefile                
  776  3.2.2013 17:51  cat ../Makefile

要使用它，请将附加的文件放到您的目录中$fpath，然后将以下行添加到您的~/.zshrc：

zstyle ':completion:*:historyevent' command 'fc -dE -lr 1'
zstyle ':completion:*:historyevent' sort no

最后，开始一个新的zsh会话。

请注意，这是一个快速而粗糙的解决方案，但它现在已经运行良好一段时间了。

_historyevent

#autoload

local out histevent list expl match desc listargs all nm ret=1

_tags historyevent || return 1

all=(-U)
match="*[[:blank:]]*[[/[:blank:]]$PREFIX*$SUFFIX*"
nm="$compstate[nmatches]"

out=( "${(@f)$(_call_program historyevent fc -l 2>/dev/null)}" )
desc="$out[1]"
out=( "${(@M)out[2,-1]:#${~match}}" )

histevent=( "${(@)${(@M)out##[^0-9]#[0-9]#}##*[[:blank:]]}" )

if zstyle -T ":completion:${curcontext}:historyevent" verbose; then
  list=( "${(@Mr:COLUMNS-1:)out}" )
  desc=(-ld list)
else
  desc=()
fi

_wanted processes expl 'history event' \
    compadd "$@" "$desc[@]" "$all[@]" -a - histevent && ret=0

if [[ -n "$all" ]]; then
  zstyle -s ":completion:${curcontext}:historyevent" insert-ids out || out=menu

  case "$out" in
  menu)   compstate[insert]=menu ;;
  single) [[ $compstate[nmatches] -ne nm+1 ]] && compstate[insert]= ;;
  *)      [[ ${#:-$PREFIX$SUFFIX} -gt ${#compstate[unambiguous]} ]] &&
              compstate[insert]=menu ;;
  esac
fi

return ret

_fc

#compdef fc

local curcontext="$curcontext" line state ret=1

_arguments -C \
   '-e[editor command]' \
   '-l[list last history events]' \
   '-n[suppress numbers]' \
   '-r[reverse order]' \
   '*:history event:->historyevent' && ret=0

if [[ -n "$state" ]]; then
  _alternative \
    'historyevent:: _historyevent' && ret=0
fi

return ret

相关内容