Windows 版 gVim：如何正确转义与 !start 一起使用的文件名？

Question

我的 .vimrc 中有这段代码，以便可以在不同的 gVim 实例中打开不同类型的文件。

function GetSvrName(ext)
    if !exists('s:ext2srv')
        let s:ext2srv = [
                    \['PHP', ['php', 'phtml']],
                    \['JS', ['js']],
                    \['CSS', ['css']],
                    \['HTML', ['htm', 'html', 'dwt', 'lbi']],
                    \['PY', ['py']],
                    \['TXT', ['txt', 'text', 'md', 'mkd']],
                    \['C', ['c', 'cpp', 'h', 'hpp']],
                    \['LOG', ['log']],
                    \['INI', ['ini', 'conf']],
                    \['BAT', ['bat', 'sh']],
                    \]
    endif
    for srv in s:ext2srv 
        for extname in srv[1]
            if a:ext == extname
                return srv[0]
                " break
            endif
        endfor
    endfor
    return 'GVIM'
endfunction

function VimDispatch()
    if &diff || !argc()
        return 0
    endif
    let l:argv = argv()
    for a in l:argv
        let l:sp = expand('/')
        let l:lastsp = strridx(a, l:sp)
        let l:file = strpart(a, l:lastsp + 1)
        let l:lastdot = strridx(l:file, '.')
        let l:ext = strpart(l:file, l:lastdot + 1)
        let l:srvname = GetSvrName(l:ext)
        exe 'silent !start gvim --servername ' . l:srvname . ' --remote-tab-silent "' . a . '"'
        call remote_foreground(l:srvname)
    endfor
    exit
endfunction

call VimDispatch()

但它存在一些问题。一个是有些文件无法再打开。例如，当我打开一个名称包含字符串的文件时~!，会出现一个消息框：

Error detected while processing function VimDispatch:
line   12:
E34: No previous command

或者，如果文件名包含@#：

Error detected while processing function VimDispatch:
line   12:
E194: No alternate file name to substitute for '#': silent !start gvim --servername TXT --remote-tab-silent 
"D:\@#.txt"

并且文件未被打开。

那么我该如何解决这个问题，以便我的代码可以使用这些文件名？

Answer 1

这是由于您过于简单的自行引用造成的。您正在寻找命令shellescape()；对于:!，您需要传递1附加{special}参数，如下所示：

exe 'silent !start gvim --servername ' . l:srvname . ' --remote-tab-silent ' . shellescape(a, 1)