☰

在 3 列中查找唯一值

tag-icon • tag-icon microsoft-excel-2010
在 3 列中查找唯一值

我在 Excel 中有 3 列。我想在 A、B 和 C 列中查找唯一值。

所以：

  1. 通过查看 A 列，我想找到 B 或 C 中不存在的唯一值。
  2. 通过查看 B 列，我想找到 A 列或 C 列中不存在的唯一值。
  3. 通过查看 C 列，我想要找到 A 列或 B 列中不存在的唯一值。

这是我在 A 栏中输入的内容

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

这是我在 B 栏输入的内容

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

这是我在 C 栏输入的内容

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

这导致三列的值重复，我需要它们是唯一的。也许我只是把事情搞得很复杂。有什么想法可以做到这一点吗？

表格示例：

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

在此例中，我希望每列都有唯一的 #。因此，对于 A 列，B 列或 C 列中没有的唯一值 = 1,4,5,6。在 B 列中，A 列或 C 列中没有的唯一值 =8,9, 10。在 C 列中，B 列或 C 列中没有的唯一值 = 11, 12, 13。我想在 D、E、F 列中为这三个公式创建一个公式。

ABC 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

在此例中，我想要每列中唯一的 #。因此，对于 A 列，不在 B 列或 C 列中的唯一值 = 1,4,5,6。在 B 列中，不在 A 列或 C 列中的唯一值 =8,9, 10。在 C 列中，不在 B 列或 C 列中的唯一值 = 11, 12, 13。我想在 D、E、F 列中为这三个公式创建一个公式。

答案1

您可以在 D1 中使用如下所示的数组公式† ：

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

其他列的公式类似：

E1：

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1：

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

从您的示例表中，我得到了这些：

在此处输入图片描述

如果公式从不同于第一行的行开始，则公式将需要稍微改变，因为它使用的公式ROW()取决于公式所在的行。

†注意：要使用公式，您必须在插入公式后按住Ctrl+Shift然后再按。Enter

相关内容