我有一个包含数千行联系信息的 Excel 文件。
我需要获取所有具有重复名字和姓氏的行的列表。
我已经能够使用条件格式来突出显示具有重复名称的行，但我希望能够获取所有重复项的列表。
举个例子，我的列表如下：
First Name Last Email Phone
Tim Berly [email protected] 454-343-2123
Tim Berly [email protected] 343-234-2343
Mary Berly [email protected] 333-212-6996
Jill Brown [email protected] 334-343-3443
Mary Red [email protected] 444-454-4545
Mary Red [email protected] 333-333-2222
Bryan Weasel [email protected] 333-444-2235
我正在尝试做这样的事情：如果名字和姓氏有重复，则添加值=1 的新列。
Has Dup? First Name Last Email Phone
1 Tim Berly [email protected] 454-343-2123
1 Tim Berly [email protected] 343-234-2343
Mary Berly [email protected] 333-212-6996
Jill Brown [email protected] 334-343-3443
1 Mary Red [email protected] 444-454-4545
1 Mary Red [email protected] 333-333-2222
Bryan Weasel [email protected] 333-444-2235
感谢您的帮助。
答案1
添加新列后，似乎名在 B1 中。在 A2 中，您可以添加以下任一公式，
=COUNTIFS(B:B, B2, C:C, C2)
这将计算出名字和姓氏出现的次数（例如1对于单身人士，2或更多的重复项）。
如果你想要一个更复杂的公式和更简单的结果，那么也许，
=SIGN(COUNTIFS(B:B, B2, C:C, C2)-1)
这将产生0对于单次发生的情况和1对于任何重复、三重等。这可以扩展为一个IF语句，该语句留下一个空字符串对于单身人士来说。
=IF(COUNTIFS(B:B, B2, C:C, C2)>1, 1, "")
这是最接近您在样本中显示的结果。其中任何一个都应该可以识别重复项；这取决于您想要如何呈现结果。下一个（也是最后一个）选项将仅显示第二个（或第三个，等等）出现的情况。
=IF(SIGN(COUNTIFS(B$2:B2, B2, C$2:C2, C2)>1), 1, "")
因此，这不能识别重复值的第一次出现，但它可以识别第二次、第三次等1。
根据需要，将这些公式中的任何一个填写或复制到 A 列中。
答案2
如果你的名字已经排序，你可以使用
=AND($B2=$B3, $C2=$C3)
从第 3 行开始。这将报告TRUE与上一行具有相同名字和姓氏的每一行。如果您需要显示的结果（与上一行相同或以下），A2设置
=AND($B2=$B3, $C2=$C3)
并A3
=OR(AND($B2=$B3, $C2=$C3), AND($B3=$B4, $C3=$C4))
（并向下拖动）。
如果您更喜欢1and0而不是TRUEand FALSE，则公式以 开头--；例如，
=--OR(AND($B2=$B3, $C2=$C3), AND($B3=$B4, $C3=$C4))
请注意，此答案要求您的数据按以下方式排序：最后名称。如果您有
Tim Berly ...
Mary Berly ...
Tim Berly ...
这不会抓住它。