☰

如何将字符串从 AA 增加到 AB？

tag-icon • tag-icon microsoft-excel
如何将字符串从 AA 增加到 AB？

我在 Excel 中有类似AA或 的字符串XA。

我需要像这样增加它们：

对于AA单元格 A1 来说，它将位于AB单元格 B1 中，AC单元格 B2 中，以此类推。

对于XA单元格 A1 来说，它将位于XB单元格 B1 中，XC单元格 B2 中，以此类推。

我尝试了流行的代码，=CHAR(CODE(A1)+1)但是在 Z 之后它不起作用。

欢迎任何提示。

答案1

试试这个：将“AA”输入单元格A1并在单元格中输入以下公式B1并拖动

=IF(RIGHT($A1,1)="Z", CHAR(CODE(LEFT(A1,1))+1),LEFT(A1,1))&CHAR(65+MOD(CODE(RIGHT(A1,1))+1-65,26))

它将按如下方式递增：AA、AB、AC、...、AZ、BA、BB、BC.... 等

您可能需要调整此公式以适合您的特定演示。请注意，此公式在“ZZ”之后无效。

更新：修复错误

答案2

我们可以使用 Excel 电子表格本身来帮助增加字母 - 增量将从A到XFC

首先创建单元格引用： INDIRECT(A1&"1")
然后找到下一列的地址： ADDRESS(1,COLUMN(INDIRECT(A10&"1"))+1)

然后从 $??$1 中提取字母：2 种方法：

  1. 找到第二个 $，然后剪掉它们之间的文字

    =MID(ADDRESS(1,COLUMN(INDIRECT(A1&"1"))+1),2,FIND("$",ADDRESS(1,COLUMN(INDIRECT(A1&"1"))+1),2)-2)

  2. 将字符串中的 1 和 $ 替换为空

    =SUBSTITUTE(SUBSTITUTE(ADDRESS(1,COLUMN(INDIRECT(A1&"1"))+1),"$",""),"1","")

选择最适合您的方案

答案3

另一个示例：在单元格 A1 中输入此公式，然后将公式复制到任意或所有单元格。

=CHAR(MOD(行(A1)-1;26)+65)&CHAR(MOD(列(A1)-1;26)+65)

旨在作为人们如何思考这个问题的一个例子。

答案4

另一种解决方案ADDRESS()是使用：

=MID(ADDRESS(1,26+ROW()),2,2)

上述公式将返回AA第一行和AB第二行，依此类推。

同样，使用数学公式是：

=CONCATENATE(CHAR(INT(ROW()/26)+65),CHAR(MOD(ROW()-1,26)+65))

相关内容