☰

提取多部分 rar，提取时删除部分

tag-icon • tag-icon windows compression rar
提取多部分 rar，提取时删除部分

我有一个解压后大小为 80GB 的多部分 rar 文件。我有 5GB 的可用空间，rar 档案的每个部分都是 2GB。

我想要的是提取一个部分，删除它，提取下一个部分，依此类推，以便在提取过程中最多使用 5 GB 而不会耗尽我所有的磁盘空间。

答案1

重要的：

  • 这个脚本将要无论最终结果如何，都会删除已完成提取的部分，因此如果该过程因丢失或损坏的部分而停止，您将无法重新开始
  • 打开记事本并粘贴以下代码并保存为解压文件与您的 rar 文件位于同一文件夹中。
  • 放UnRAR_完整路径，第一部分和目标文件夹，请务必保留引号。

剧本：

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

选项一：沉默的

跑过解压文件双击文件

选项二：受到推崇的

去除‘从一开始

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

打开 cmd，直接进入你的文件夹并输入“cscript _unrar.vbs”

  • 使用WScript.Echo没有脚本会弹出太多烦人的消息框

该脚本通过读取 UnRAR.exe 的标准输出来工作。

编辑

改进了脚本，使其可以自动处理任何名称结构和最多 9999 个部分的任意数量的部分，并处理不包含前导零的旧档案。

相关内容