☰

如何在PC上批量安装安装文件（*.exe）？

tag-icon • tag-icon windows installation batch setup portable
如何在PC上批量安装安装文件（*.exe）？

不用反复双击数十个安装文件 (*.exe)，可以一次性批量安装吗？或者至少双击一次就可以依次激活它们？

最接近的 Google 解决方案是尼尼特和快速安装。但是，两者都只提供一些预设的、众所周知的程序的选择，无法自定义到包含我存储的一些 (*.exe) 文件。

考虑到未来可预见的重复过程，有没有办法解决这个问题？

答案1

常见的安装程序都有“静默安装”选项。例如，Innosetup 有用/VERYSILENT /SUPPRESSMSGBOXES /NORESTART /DIR="C:\INSTALL\PATH"于此目的的命令行选项，而 NSIS 安装程序有/S /D=C:\Install Path\No Quotes Allowed Even If Space Present。

看无人值守安装了解更多信息。

当然，静默安装提供的选择很少，例如，您无法决定是否安装 32 位或 64 位 R 包，而是同时安装两者。

作为示例，下面是我创建的批处理文件，用于自动将 TeXmacs 和 maxima 安装到我教室的多媒体系统中。其中的两个子程序可能会有用。

setlocal

set "main_dir=%USERPROFILE%\DESKTOP"
set "TeXMacs_dir=%main_dir%\mathsofts\TeXMacs"
set "maxima_dir=%main_dir%\mathsofts\maxima"

call :silent_install_inno "%~dp0TeXmacs.exe" "%TeXMacs_dir%"
call :silent_install_nsis "%~dp0maxima.exe" "%maxima_dir%"

endlocal
exit /b

:silent_install_inno
:: parameters: %1--path to the installer executable
::             %2--installation path
start "" /wait %1 /VERYSILENT /SUPPRESSMSGBOXES /NORESTART /DIR=%2
exit /b

:silent_install_nsis
:: parameters: %1--path to the installer executable
::             %2--installation path
:: note: NO QUOTES in %2 is allowed, so %~2 should be used to de-quote
start "" /wait %1 /S /D=%~2
exit /b

相关内容