如何更改 Microsoft Word 2011 for Mac 中注释区域的宽度

Question 1

我无法在用户界面中看到任何可以执行此操作的工具，但您可以在代码中执行此操作。像往常一样，步骤比我想要的多得多。在底部，我现在为熟悉的人添加了一些 VBA 以插入您的 Normal 模板中。

对于 VBA，不太确定您是否需要启用“开发人员”选项卡，但是...

打开您的文档并启用您想要更改的视图（不同视图的宽度可能不同）。

单击 Word->工具->宏->Visual Basic 编辑器。

理想情况下，尝试组织 Word 和 VBE 窗口，以便您可以单击两个窗口而不隐藏其中一个。

如果您在 VBE 中看不到标题为“立即窗口”的窗口，请使用 VBE 的视图->立即窗口来显示它

在立即窗口中输入以下内容，或从此处复制/粘贴，然后在末尾按回车键

?activewindow.view.revisionsballoonwidthtype

我认为您将在立即窗口中看到值“1”。如果是这样，请将命令更改为以下内容（删除“？”并附加“=0”）

activewindow.view.revisionsballoonwidthtype=0

并执行它

然后将命令更改为

activewindow.view.revisionsballoonwidth=10

（将您想要的百分比放在我输入的“10”的位置）并执行该操作。

如果你确实想要以点为单位的宽度，请执行

activewindow.view.revisionsballoonwidthtype=1

然后执行

activewindow.view.revisionsballoonwidth=200

其中宽度以磅为单位，而不是“200”

笔记：

当我第一次尝试更改宽度值时，它不起作用。我似乎必须先修改 revisionsballoonwidthtype，然后我的更改才会“生效”，但也许我在此过程中做错了什么。
您可能需要在“ActiveWindow”前面加上“ActiveDocument。” (不带引号) 才能使其正常工作。

无论如何，我会给你等效的 applescript，但我在 Word 2011 词典中看不到等效的属性名称。

或者，您可以将以下代码放入 Normal 模板中的新模块中（您可以在 VB 编辑器中执行此操作）。将顶部的宽度值更改为您想要使用的宽度值。然后，使用空白文档（即“基于”Normal.dotm），运行 @@@ 例程。这应该可以修复 normal.dotm 本身并在将来更改默认行为（我认为！）。

但是，其中还有一个 AutoOpen 例程，你可以可能需要更改现有文档的设置。我不确定您是否需要这样做。如果不需要，请删除或重命名 AutoOpen 子项。如果您确实需要它，并且您的 Normal.dotm 中已经有 AutoOpen，则需要修改现有例程，然后删除/重命名我的例程。

在此过程中，我意识到存在最小宽度，这让我认为这些值没有“生效”。但例如，在这里设置 5%、10%、15% 的宽度会产生完全相同的效果，我需要将其设置为 21% 或类似的值来增加它。Word 不会报告宽度它检查值时设置 - 它会报告宽度尝试过进行设置。如果您想要“最小值”，我想使用值“1”可能就足以达到点数或百分比的要求。

' set your preferred measurement type and width here.
' NB, there seems to be a minimum anyway, but that may depend on things I have
' not looked at such as screen size and so on.
' The numbers Word reports are the numbers you have set, not the values
' it has actually set the width to.
'Const preferredBalloonWidthType As Integer = WdRevisionsBalloonWidthType.wdBalloonWidthPoints
'Const preferredBalloonWidth As Single = 300
Const preferredBalloonWidthType As Integer = WdRevisionsBalloonWidthType.wdBalloonWidthPercent
Const preferredBalloonWidth As Single = 25

Sub autoopen()
Call changeBalloonSettings
End Sub

Sub changeBalloonSettings()
  With ActiveWindow.View
    .RevisionsBalloonWidthType = preferredBalloonWidthType
    .RevisionsBalloonWidth = preferredBalloonWidth
    ' debug check
    'If .RevisionsBalloonWidthType = WdRevisionsBalloonWidthType.wdBalloonWidthPercent Then
    '  MsgBox "Percent: " & .RevisionsBalloonWidth
    'Else
    '  MsgBox "Points: " & .RevisionsBalloonWidth
    'End If
  End With
End Sub

Sub fixupNormaldotm()
' Sets the Normal template to have the settings we would like
' for future documents
' to run this, start word and ensure that a single blank doument,
' based on Normal.dotm, is open (this is by default what you get
' when you start the Word application without e.g. double-clicking
' on a doument in Finder)
Dim d As Word.Document
Dim t As Word.Template
Set t = ActiveDocument.AttachedTemplate

Set d = Documents.Open(t.FullName)
' autoopen should run, so that's all we need. If you removeed
' autoopen, uncomment the following line:
call changeBalloonSettings
d.Save
d.Close
Set d = Nothing
Set t = Nothing
End Sub

Answer