Autohotkey：使用 Space + Alt + q 触发操作

Question 1

我之所以继续发帖是因为您继续尝试不同的建议和组合，而不仅仅是要求别人编写您的脚本。

我将复制/粘贴/修改几个按键定义示例，希望让您了解可以实现此目的的不同方式（可能已经提到过，也可能没有提到过），并希望让您更好地理解可以使用的各种逻辑组合，而不仅仅是解决您的特定按键组合问题。希望如果我不直接解决它，您能够弄清楚。

例如：仅当按下空格键时才触发。

#If GetKeyState("Space", "P")   ; All hotkeys below won't trigger unless space is pressed
q::
    ToolTip % "Space+q pressed..."
    Sleep 500
    ToolTip
Return

!q::
    ToolTip % "Space+Alt+q pressed..."
    Sleep 500
    ToolTip
Return
#If

示例：热键代码中的多个修饰符检查的特定触发器。

#If WinActive("ahk_class xxx") || WinActive("ahk_class YYY")
*q::        ; * Triggers for all/multiple modifiers.  q keypress is discarded.

    If !(GetKeyState("Alt", "P") && GetKeyState("Space", "P"))
        Return  ; continue no further unless Alt+Space are also pressed.  q keypress is discarded

    ; This code below will execute for Alt+Space-q and also Alt+Space+Control+q (i.e., * modifiers that haven't been excluded via test above)
    ToolTip % A_ThisHotkey " pressed..."
    Sleep 500
    ToolTip
Return

示例：手动发送按键（即热键修饰符过滤）

#If WinActive("ahk_class xxx") || WinActive("ahk_class YYY")
*q::        ; * Triggers for all/multiple modifiers

    If !(GetKeyState("Alt", "P") && GetKeyState("Space", "P")) {
        SendInput {Blind}q      ; send q keystroke and allow any pressed modifiers to stay in tact.  If Control is down, Control+q will get sent
        Return  ; continue no further unless Alt+Space are also pressed.  
    }

    ; This code below will execute for Alt+Space-q and also Alt+Space+Control+q (i.e., * modifiers that haven't been excluded via test above)
    ToolTip % A_ThisHotkey " pressed..."
    Sleep 500
    ToolTip
Return

示例：无论您是否执行操作，按键都会被发送到程序。

#If WinActive("ahk_class xxx") || WinActive("ahk_class YYY")
~*q::       ; * Triggers for all/multiple modifiers; ~ allow passthrough so keystroke is not discarded

    If !(GetKeyState("Alt", "P") && GetKeyState("Space", "P"))
        Return  ; continue no further unless Alt+Space are also pressed.  q keypress has already passed through to program

    ; This code below will execute for Alt+Space-q and also Alt+Space+Control+q (i.e., * modifiers that haven't been excluded via test above)
    ToolTip % A_ThisHotkey " pressed..."
    Sleep 500
    ToolTip
Return

示例：单个热键中的多个定义/操作（有效但不推荐实施）。

#If WinActive("ahk_class xxx") || WinActive("ahk_class YYY")
*q::        ; * Triggers for all/multiple modifiers; ~ allow passthrough so keystroke is not discarded

    If !GetKeyState("Space", "P")
        Return  ; continue no further unless Alt+Space are also pressed.  q keypress is discarded

    If (GetKeyState("Alt", "P") {
        ToolTip % "Alt+Space+q (and possibly other modifiers) pressed..."
        Sleep 500
        ToolTip
    } Else {
        ToolTip % "Space+q (and possibly other modifiers) pressed..."
        Sleep 500
        ToolTip
    }
Return

您可以区分热键定义中的键并有选择地执行不同的代码集，但一般的最佳做法可能是使用#If语句来确定热键代码的执行时间。

不要#If's连续使用两个...热键定义由#If热键定义语句之前的最后一个连续语句决定...

; Do Not Use...
#If WinActive("ahk_class xxx") || WinActive("ahk_class YYY")
#If (GetKeyState("Alt", "P")) && (GetKeyState("Space", "P"))    ; this voids the #If statement above

应该如下所示。

; If ahk_class xxx or yyy, and if Alt+Space is also pressed...
#If (WinActive("ahk_class xxx") || WinActive("ahk_class YYY"))  && (GetKeyState("Alt", "P") && GetKeyState("Space", "P"))   
; ...
; code goes here
; ...
#IfWinActive ; this sets context for the next hotkeys back to default; only one statement needed; indentation is irrelevant

请注意，根据需要使用分组括号来进行逻辑 OR/AND 组合......在某些情况下，可以不用它们，但是在混合 AND 和 OR 时要小心地组合语句。

由于布尔运算符被识别为延续最后一行，因此该语句也可以自动延续两行（为了风格/可读性）......

#If (WinActive("ahk_class xxx") || WinActive("ahk_class YYY"))  
&& (GetKeyState("Alt", "P") && GetKeyState("Space", "P"))
;q::    ; q hotkey without modifiers will never trigger here because Alt must be down to get this far
!q::    ; this will trigger
    ToolTip % "Space+Alt+q pressed..."
    Sleep 500
    ToolTip
Return
!d::
    ToolTip % "Space+Alt+d pressed..."
    Sleep 500
    ToolTip
Return
#If

示例：拆分处理（内部/外部热键定义）（可行但不推荐实施）

#If (WinActive("ahk_class xxx") || WinActive("ahk_class YYY"))
!q::
    If GetKeyState("Space", "P") {
        ToolTip % "Space+Alt+q pressed..."
        Sleep 500
        ToolTip
    } Else {
        ToolTip % "Alt+q pressed..."
        Sleep 500
        ToolTip
    }
Return
#If

示例：热键定义内的所有处理（可用但不推荐实现）

!q::
    If !(WinActive("ahk_class xxx") || WinActive("ahk_class YYY"))
        Return

    If GetKeyState("Space", "P") {
        ToolTip % "Space+Alt+q pressed..."
        Sleep 500
        ToolTip
    } Else {
        ToolTip % "Alt+q pressed..."
        Sleep 500
        ToolTip
    }
Return
#If

最后的例子是根据需要在热键之间拆分代码，#If并向下选择语句以始终保持某个类窗口处于活动状态并且按下空格键......

#Persistent
Return


#If (WinActive("ahk_class xxx") || WinActive("ahk_class YYY")) 
 && GetKeyState("Space", "P")   ; All hotkeys below won't trigger unless space is pressed

;!Space::Return     ; Optional. Kill the window system menu if present

q::
    ToolTip % "Space+q pressed..."
    Sleep 500
    ToolTip
Return

!q::
    ToolTip % "Space+Alt+q pressed..."
    Sleep 500
    ToolTip
Return

d::
    ToolTip % "Space+d pressed..."
    Sleep 500
    ToolTip
Return

!d::
    ToolTip % "Space+Alt+d pressed..."
    Sleep 500
    ToolTip
Return
#If

Space请注意，这不会使或作为独立按键的使用无效Alt+Space。例如，如果您按下Space然后Alt按下热键，它将Space在执行Alt+hotkey代码之前发送一个。同样，如果您按下Alt+Space（例如在普通窗口中），它将触发左上角的系统窗口（恢复/移动/大小/最小化/最大化/关闭）。热键功能仍然有效，但下拉菜单可能会很烦人（如果您不在已经排除此菜单的工具窗口中），在这种情况下，您还可以添加一个!Space::Return函数来终止功能，Alt+Space同时保留热键。在这种情况下，它应该添加到上下文块（相关#If语句）中，以便它仅适用于该特定窗口。

还有多种其他方法可以让代码针对这些组合键执行，而无需使用 GetKeyState()（如其他一些答案中所述）——我不会重复这些信息。您应该能够获得一些答案组合来执行您想要的操作。

Answer