☰

有没有办法在批处理脚本中推送和弹出所有环境变量？

tag-icon • tag-icon batch environment-variables
有没有办法在批处理脚本中推送和弹出所有环境变量？

有没有办法在批处理脚本中推送和弹出所有环境变量？例如，我想做这样的事情：

pushEnvironmentVariables
call "%VS140COMNTOOLS%\vsvars32.bat"
(do some stuff...)
popEnvironmentVariables
pushEnvironmentVariables
call "%VS90COMNTOOLS%\vsvars32.bat"
(do some other stuff...)
popEnvironmentVariables

答案1

使用 setlocal，参见setlocal /?或ss64.com/nt/setlocal

Setlocal
call "%VS140COMNTOOLS%\vsvars32.bat"
(do some stuff...)
Endlocal
Setlocal
call "%VS90COMNTOOLS%\vsvars32.bat"
(do some other stuff...)
Endlocal

要保存当前变量状态，你可以这样做

set >MyVarStatus.txt

稍后恢复

@Echo off
For /f "tokens=1* delims==" %%A in (
  'findstr /V "^Path" MYVarStatus.txt '
) Do Set %%A=%%B

这将排除路径变量。

答案2

虽然有点晚了，但还是要说一下。下面是 Windows 批处理脚本中堆栈数据结构的实现。

特征：

  • 您必须致电:初始化堆栈子程序在使用堆栈之前。
  • 通过调用：推子程序。
  • 通过调用：流行音乐子程序。
  • 变量$Count将始终包含堆栈中的项目数。
  • 变量$Top将始终包含添加到堆栈的最新项目。
  • 变量$底部将始终包含添加到堆栈的第一个项目。
  • 您可以通过调用:转储堆栈子程序。
  • 可以推送到堆栈上的项目类型是可以存储在变量中的任何内容。例如，调用：按下“字符串 1”，调用：推送“%1”，调用：推送“％MyVariable％”， ETC。

我在批处理文件中使用堆栈来跟踪子程序调用。我的批处理文件中的每个子程序都以呼叫：推 %0，将当前子程序的名称推送到堆栈上，并以呼叫：流行。

有些人可能会觉得它对于批处理脚本来说有点大材小用，但我很喜欢创建它，我希望有人会觉得它很有用，享受。

@Echo Off
Cls
SetLocal
SetLocal EnableExtensions
SetLocal EnableDelayedExpansion

Call :InitializeStack

Call :Push "String 1"
Call :Push "String 2"
Call :Push "String 3"
Call :Pop

Echo Total items in stack = !$Count!
Echo Top of stack         = !$Top!
Echo Bottom of stack      = !$Bottom!
Call :DumpStack

Goto End

:InitializeStack
:------------------------------------------------------------
Set "$Stack[0]=0"
Set "$Count=!$Stack[0]!"
Set "$Top="
Set "$Bottom="
Exit /b

:DumpStack
:------------------------------------------------------------
If !$Stack[0]! EQU 0 (
  Echo Stack is empty.
) Else (
  Echo.
  Echo Stack Dump
  Echo ----------
  For /l %%a In (!$Stack[0]!,-1,1) Do (Echo !$Stack[%%a]!)
)
Exit /b

:Push <String>
:------------------------------------------------------------
Set /a "$Stack[0]+=1"
Set "$Count=!$Stack[0]!"
Set "$Top=%~1"
Set "$Bottom=!$Stack[1]!"
Set "$Stack[!$Stack[0]!]=!$Top!"
Exit /b

:Pop
:------------------------------------------------------------
If !$Stack[0]! EQU 0 (
  Echo "Stack is empty."
) Else (
  Set "$Stack[!$Stack[0]!]="
  Set /a "$Stack[0]-=1"
  Set "$Count=!$Stack[0]!"
  If !$Stack[0]! GTR 0 (
    For %%a In (!$Stack[0]!) Do Set "$Top=!$Stack[%%a]!"
    Set "$Bottom=!$Stack[1]!"
  ) Else (
    Set "$Top="
    Set "$Bottom="
  )
)Exit /b

:PushAllEnvironmentVariables
:------------------------------------------------------------
For /f "Tokens=* Delims=" %%a In ('Set') Do Call :Push "%%a"
Exit /b

:PopAllEnvironmentVariables
:------------------------------------------------------------
For /l %%a In (!$Stack[0]!,-1,1) Do (Set !$Stack[%%a]!)
Exit /b

:End

因此，要推送所有环境变量，可以调用：PushAllEnvironmentVariables；要恢复所有环境变量，可以调用：PopAllEnvironmentVariables

相关内容