☰

如何按字母顺序对 Excel 工作表进行排序？

tag-icon • tag-icon microsoft-excel vba microsoft-excel-2007 macros
如何按字母顺序对 Excel 工作表进行排序？

我发现这个问题但我无法找到仅按字母顺序排序的部分。

我该如何举例说明呢？

答案1

在要组织的 Excel 工作簿中，打开 VBA（alt+F11），插入一个新模块（插入>模块）并复制并粘贴以下宏代码：

Sub Sort_Active_Book()
Dim i As Integer
Dim j As Integer
Dim iAnswer As VbMsgBoxResult
'
'
   iAnswer = MsgBox("Sort Sheets in Ascending Order?" & Chr(10) _
     & "Clicking No will sort in Descending Order", _
     vbYesNoCancel + vbQuestion + vbDefaultButton1, "Sort Worksheets")
   For i = 1 To Sheets.Count
      For j = 1 To Sheets.Count - 1
'
' If the answer is Yes, then sort in ascending order.
'
         If iAnswer = vbYes Then
            If UCase$(Sheets(j).Name) > UCase$(Sheets(j + 1).Name) Then
               Sheets(j).Move After:=Sheets(j + 1)
            End If
'
' If the answer is No, then sort in descending order.
'
         ElseIf iAnswer = vbNo Then
            If UCase$(Sheets(j).Name) < UCase$(Sheets(j + 1).Name) Then
               Sheets(j).Move After:=Sheets(j + 1)
            End If
         End If
      Next j
   Next i
End Sub

关闭并返回 Excel，然后运行宏 (alt+F8)。这将显示一个对话框，让您可以选择按字母顺序升序或降序排序。

感谢 HowToGeek 提供此内容。几个月前，我在被（不懂电脑的）老板纠缠时发现了它。

希望能帮助到你。

编辑：如果您想保存宏以便在电子表格中进一步使用，请确保将其保存为“启用宏的工作簿”！

相关内容