☰

Microsoft Excel，一个单元格中多个公式

tag-icon • tag-icon microsoft-excel
Microsoft Excel，一个单元格中多个公式

我需要一些关于在一个单元格中放置多个公式的帮助。

如果我在 g11 中输入 1，我希望它使用以下公式 =if(H11="","",I11/(230*H11))

如果我在 g11 中输入 3，我希望它使用以下公式 =if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

提前致谢

答案1

您也可以使用相同的 IF 函数来测试 G11 单元格：（在单行中使用此公式）

=if(G11=1,  
    if(H11="","",I11/(230*H11)), 
    if(G11=3, 
            if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),
            ""
      )
   )

=if(G11=1,测试它的值是否为 1
        if(H11="","",I11/(230*H11)),真条件运行你的公式 1
        if(G11=3,如果它是假，测试它的值是否为 3
              if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),如果 G11 是 3 然后运行你的第二个公式
              ""如果 G11 是其他的东西什么也不做
      )关闭如果（G11=3,,）
)关闭如果（G11=1,,）

答案2

怎么样

 =IF(G11=1,IF(H11="","",I11/(230*H11)),IF( G11=3,IF(H11="","",I11/(SQRT(3)*400*H11*(E11/100))),""))

答案3

你肯定注意到了，你的两个（可选）公式是非常相似的：

=if(H11="","",I11/(230        *H11          ))
 ↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕           ↕↕↕↕          ↕↕
=if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

并且可以重新排列第二个公式来简化它并增加相似度：

 400*H11*(E11/100)
=400*(E11/100)*H11
=(400*E11/100)*H11
=(E11*400/100)*H11
=E11*(400/100)*H11
=E11 *   4   * H11
=4*E11*H11

所以你的第二个公式简化为

=if(H11="","",I11/(sqrt(3)*4*E11*H11))

我们可以利用这种相似性来简化整体公式（在其他几个答案中已经给出）

=if(H11="","",I11/(IF(G11=1,230,IF(G11=3,sqrt(3)*4*E11,0))*H11))

请注意，如果G11除 1 或 3 之外，则明确除以 0，这将导致错误。如果这对您来说是个问题，请不要使用此答案。

相关内容