☰

Excell 单元格计算

tag-icon • tag-icon microsoft-excel
Excell 单元格计算

我可以在 Excel 中设置一个单元格，使其包含公式吗？这样，当我将数字写入该单元格时，它会自动将该公式应用于该单元格，并显示计算出的数字。

即，如果我想在单元格 A1 中写入一个数字，比如 10；但我希望单元格 (A1) 计算 10 的 125%。结果为 12.5；显示在单元格 A1 中

答案1

将以下工作表事件宏放置在工作表代码区域：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rINT As Range
    Set rINT = Intersect(Target, Range("A1"))
    If rINT Is Nothing Then Exit Sub
    Application.EnableEvents = False
        Range("A1").Value = 1.25 * Range("A1").Value
    Application.EnableEvents = True
End Sub

因为它是工作表代码，所以非常容易安装和自动使用：

  1. 右键单击 Excel 窗口底部附近的选项卡名称
  2. 选择查看代码-这将打开一个 VBE 窗口
  3. 粘贴内容并关闭 VBE 窗口

如果您有任何疑虑，请首先在试用工作表上尝试一下。

如果您保存工作簿，宏将随之保存。如果您使用的是 2003 以后的 Excel 版本，则必须将文件保存为 .xlsm 而不是 .xlsx

要删除宏：

  1. 调出如上所示的 VBE 窗口
  2. 清除代码
  3. 关闭 VBE 窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其工作！

编辑＃1：

要对一组单元格执行此操作，请说A1通过A10，将之前的宏替换为：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rINT As Range, r As Range
    Set rINT = Intersect(Target, Range("A1:A10"))
    If rINT Is Nothing Then Exit Sub
    For Each r In rINT
        Application.EnableEvents = False
            r.Value = 1.25 * r.Value
        Application.EnableEvents = True
    Next r
End Sub

相关内容