☰

日期之间的 SUMIF 条件

tag-icon • tag-icon microsoft-excel worksheet-function
日期之间的 SUMIF 条件

我有成本表、成本增加日期、实际收到成本的日期。成本格式为货币。计划收货日期是下拉选择，实际收货格式如下，例如

Cost | Planned Recieve Date | Actual Goods Receipt
$XYZ | Apr-18               | 11 April 2018
$XYZ | Apr-18               | 24 April 2018
$XYZ | Apr-18               | 28 April 2018

我想要做的是查看所有成本的总和预期的在特定月份筹集的资金是多少，实际上在给定月份收到的费用。带有日期的费用在“订购”表上，我需要的公式在另一张表上。

预期成本使用计划收货日期列。我的公式是：

= SUMIF(Ordering!$L$11:$L$365, "Apr-18", Ordering!$E$11:$E$365)

让我感到困扰的是实际收到的金额，我似乎无法正确确定标准。这使用“实际收据”列，该列具有格式化的日期。单元格显示 2018 年 4 月 24 日，单元格编辑器框中显示 2018 年 4 月 24 日。我使用的公式是：

= SUMIF(Ordering!$P$11:$P$365,">=01/04/2018 AND <=30/04/2018",Ordering!$M$11:$M$365)

这给了我一个低于我期望的值，并且我没有遗漏任何成本。（四月份只有 3 个。）我尝试了多种不同的方式来编写我的标准，并且使用了通配符。

构建我的标准的正确方法是什么，以便我可以看到给定月份内所有日期的实际收到的总成本？

答案1

您可以使用 Sumproduct 公式：

=SUMPRODUCT((MONTH(A2:A10)=4)*(MONTH(A2:A10)=4), (B2:B10))
  • A2:A10 是日期范围；
  • 4 为月份数（四月）；
  • B2:B10 是您的价格范围

答案2

硬编码公式

=SUMIFS(B2:B10,A2:A10,">=01/04/18",A2:A10,"<=30/04/18")

选项 1 - 手动将日期输入公式

=SUMIFS(B2:B10,A2:A10,">="&DATE(2018,4,1),A2:A10,"<="&DATE(2018,4,30))

选项 2 - 引用单元格中的日期

Start Date in G1
End Date in G2

=SUMIFS(B2:B10,A2:A10,">="&$G$1,A2:A10,"<="&$G$2)

选项 3 - 根据单元格引用中的月份返回 1 个月的时间段

Date reference in G1

=SUMIFS(B2:B10,A2:A10,">="&EOMONTH($G$1,-1)+1,A2:A10,"<="&EOMONTH($G$1,0))

相关内容