☰

Microsot Excel - 具有不同值的双向镜像/链接单元格（一个以百分比表示/另一个以绝对值表示）

tag-icon • tag-icon microsoft-excel vba
Microsot Excel - 具有不同值的双向镜像/链接单元格（一个以百分比表示/另一个以绝对值表示）

我将 A1 单元格格式化为货币（例如 EUR）-我手动输入基准值 -例如 1000 EUR，我想在 B1 和 C1 单元格中进行进一步计算。B1 单元格格式化为百分比（例如 20%）C1 单元格再次格式化为货币格式（EUR），我想在其中计算 EUR 的绝对值（1000 EUR 的 20% = 200 EUR）

但是 - 我想让 B1 和 C1 单元格通过各自的公式反向链接在一起，这样无论我在哪个单元格（B1 或 C1）中输入值，另一个单元格都会自动更新其结果，反之亦然。

例如，如果我在 A1 单元格中有 1000 欧元 a) 如果我在 B1 中输入 20%，则 C1 应显示结果 = 200 欧元，反之亦然 b) 当我在 C1 中输入 200 欧元时，B1 应显示 20% 的结果

您能否建议如何实现这一点？我认为需要一些代码（VBA）。非常感谢，Dusan

答案1

您可以使用工作表事件宏来执行此操作：

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count <> 1 Then Exit Sub
    If Intersect(Target, Range("B1:C1")) Is Nothing Then Exit Sub
    Application.EnableEvents = False
        If Not Intersect(Target, Range("B1")) Is Nothing Then
            [C1] = [A1] * [B1]
        Else
            [B1] = [C1] / [A1]
        End If
    Application.EnableEvents = True
End Sub

如果你更新B1，宏将会更新C1保持一致。
如果您更新C1，宏将会更新B1保持一致。
如果您更新A1宏将等待你更新B1或者C1在进行更改之前。

因为它是工作表代码，所以很容易安装并自动使用：

  1. 右键单击 Excel 窗口底部附近的选项卡名称
  2. 选择查看代码-这将打开一个 VBE 窗口
  3. 粘贴内容并关闭 VBE 窗口

如果您有任何疑虑，请首先在试用工作表上尝试一下。

如果您保存工作簿，宏将随之保存。如果您使用的是 2003 以后的 Excel 版本，则必须将文件保存为 .xlsm 而不是 .xlsx

到消除宏：

  1. 调出如上所示的 VBE 窗口
  2. 清除代码
  3. 关闭 VBE 窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其工作！

编辑＃1：

这是新代码。 TbSize是三列表格中的行数：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim TbSize As Long, rng As Range, roww As Long
    TbSize = 100
    Set rng = Range("A1:C" & TbSize)

    If Target.Count <> 1 Then Exit Sub
    If Intersect(Target, rng) Is Nothing Then Exit Sub

    roww = Target.Row
    Application.EnableEvents = False
        If Not Intersect(Target, Range("B:B")) Is Nothing Then
            Range("C" & roww) = Range("A" & roww) * Range("B" & roww)
        ElseIf Not Intersect(Target, Range("C:C")) Is Nothing Then
            Range("B" & roww) = Range("C" & roww) / Range("A" & roww)
        Else
            Range("C" & roww) = Range("A" & roww) * Range("B" & roww)
        End If
    Application.EnableEvents = True
End Sub

相关内容