☰

当数据来自另一张工作表时，如何在 VBA 中将录制的宏转换为自动宏？

tag-icon • tag-icon microsoft-excel vba macros microsoft-excel-2016
当数据来自另一张工作表时，如何在 VBA 中将录制的宏转换为自动宏？

我已录制以下宏，以根据“C3:C47”列的值对“B3:U47”范围内的数据进行排序。

Sub Sorting_Finance()
    ActiveWorkbook.Worksheets("Finance").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Finance").Sort.SortFields.Add2 Key:= _
        Range("C3:C47"), SortOn:=xlSortOnValues, Order:=xlDescending, DataOption _
        :=xlSortNormal
    With ActiveWorkbook.Worksheets("Finance").Sort
        .SetRange Range("B3:U47")
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

每次我想对数据进行排序时，我都会按 Control+n。为了在 C 列中输入新值时自动完成此操作，我尝试了以下代码：

Private Sub Worksheet_Change(ByVal Target As Range)
if not (intersect(target, Range("C3:C47")) is nothing) then 
    call Sorting_Finance
end if
end sub

但事实上，“C3:C47”列中的数据来自另一张表，因此不起作用。我能做些什么吗？

答案1

VBA 排序有两种方法。录制的版本是“普通”版本。您可以使用“简写”版本并设置主要排序顺序列，同时调整范围以适应当前数据。

顺便说一句，您应该知道您是否有标题行。xlGuess 应该替换为 xlYes 或 xlNo，我使用了 xlYes。

在模块1中：

Option Explicit

Sub Sorting_Finance()

    With ThisWorkbook.Worksheets("Finance")
        'range B3 to column U down to the last row with data in C
        With .Range(.Cells(3, "B"), .Cells(.Rows.Count, "C").End(xlUp).Offset(0, 18))
            .Sort Key1:=.Columns(2), Order1:=xlAscending, _
                  Header:=xlYes, Orientation:=xlTopToBottom
        End With
    End With

End Sub

在财务工作表代码表中，使用相同的方法定义相交范围。

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range(Cells(3, "C"), Cells(Rows.Count, "C").End(xlUp))) Is Nothing Then
        Application.EnableEvents = False
        Call Sorting_Finance
        Application.EnableEvents = True
    End If
End Sub

由于您在重新排序时更改了值，因此请禁用事件处理，以便一次迭代不会在另一次迭代之上运行。

相关内容