☰

如何禁用包含多个大写字母的单词的拼写检查？

tag-icon • tag-icon microsoft-word
如何禁用包含多个大写字母的单词的拼写检查？

例如“LaTex”、“MathJax”等。

除了将这些单词逐一添加到自定义词典中之外。

答案1

没有 Word 设置可以做到这一点。

不过，您可以使用“无拼写检查”字符样式并将其应用于单词。

此设置无论使用哪台计算机打开文档，文档中的单词都会保留，这与将单词添加到拼写检查词典不同。将单词添加到词典只会停止计算机上的标记。

下面是创建这种字符样式的宏：

Sub NoSpellCheckStyle()  ' SEE ALSO ASSIGNSHORTCUTNOSPELLCHECK FOLLOWING
    ' Charles Kenyon
    ' Creates a character style named "No Spell Check" in the Active Document
    ' Does NOT apply the style to a selection, simply creates the style
    ' 12 April 2019
    '
    Dim stlNoCheck As Style
    '
    On Error GoTo ErrorAlreadyExists
    Set stlNoCheck = ActiveDocument.Styles.Add(Name:="No Spell Check", Type:=wdStyleTypeCharacter)
    On Error GoTo -1
    With stlNoCheck
        .Font.Name = ""
        .NoProofing = True
    End With
    GoTo ExitSub
ErrorAlreadyExists:
    MsgBox Prompt:="Style 'No Spell Check' already exists", Buttons:=vbInformation, title:="Oops"
ExitSub:
    Set stlNoCheck = Nothing
End Sub

这是一个单独的宏，用于为字符样式分配键盘快捷键：

Sub AssignShortcutNoSpellCheck()
'
' Charles Kenyon ---- GOES WITH PREVIOUS MACRO
' 2 March 2021
' Assigns keyboard shortcut Ctrl+Shift+Alt+N to No Spell Check style
'   Style must exist
'   Saves this in the active document
'
    CustomizationContext = ActiveDocument ' Change ActiveDocument to NormalTemplate if style is in Normal Template
    KeyBindings.Add KeyCode:=BuildKeyCode(wdKeyN, wdKeyControl, _
        wdKeyShift, wdKeyAlt), _
        KeyCategory:=wdKeyCategoryStyle, _
        Command:="No Spell Check"
End Sub

如果需要，您可以将键盘快捷键更改为其他快捷键。

请注意，使用字符样式后，可以使用Ctrl+Spacebar返回底层段落样式。

对于文档中已有的单词，您可以选择该单词并应用字符样式。

打字时，您需要打开字符样式，然后输入 Word，然后按Ctrl+ Spacebar。

请记住，“不检查”属性是一种不可见的格式代码，它的作用类似于大胆的当你打字时它会继续运行，只是你看不到它。

相关内容