☰

Excel COUNTIFS 用于 CSAT 评分，包括零但没有空白单元格

tag-icon • tag-icon microsoft-excel worksheet-function
Excel COUNTIFS 用于 CSAT 评分，包括零但没有空白单元格

我有一组来自客户调查评级的数据，0-10，以及未给出评级的数据（显示为空白）。A 列包含代理名称，G 列包含评级。

在另一个电子表格中，我有一个小网格，行中写有代理名称，列中写有“正面 9-10”、“中立 6-8”和“差 0-5”。我尝试过的所有公式都无法正确计算 3 个标准范围内的值，也无法计算零的数量，但无法计算空白单元格。这也需要引用 A 列中的名称。因此，实际上 Joe Smith 有 3 个正面、0 个中立和 1 个差，尽管 Joe 完成了 10 份调查，但其中只有 4 份公布了数字等级。

我尝试了以下操作，其中 N49 是 A 列中的代理名称，然后 G 是评级......

=COUNTIFS('Surveys'!A$2:A$2001,N49,'Surveys'!G$2:G$2001,">=0",'Surveys'!G$2:G$2001,">=5",'Surveys'!G$2:G$2001,"<>")

=COUNTIFS('Surveys'!A$2:A$2001,N49,'Surveys'!G$2:G$2001,">=0",'Surveys'!G$2:G$2001,">=5",'Surveys'!G$2:G$2001,”<>”&””)

=COUNTIFS('Surveys'!A$2:A$2001,N49,'Surveys'!G$2:G$2001,">=0" "&<=5",'Surveys'!G$2:G$2001,"<>")

第一个公式似乎最接近我的需要，但它计算任何等级，而不仅仅是 0-5 范围内。

我对阳性结果的公式没有异议，因为

=COUNTIFS('Surveys'!A$2:A$2001,N49,'Surveys'!G$2:G$2001,">=9")

但是，当使用此公式时，我也遇到了与 Neutrals 6-8 相同的问题：

=COUNTIFS('Surveys'!A$2:A$2001,N49,'Surveys'!G$2:G$2001,">5",'Surveys'!G$2:G$2001,">9")

任何帮助都将不胜感激，谢谢！

答案1

初始说明

  • COUNTIFS 不等同0于NULL
  • 您混入了无效的引号”<>”&””)。有效"无效”可能从其他来源复制代码。

带命名范围的公式

范围名称为：
Agent:   A2:Ax
Rating:B2:Bx

           H
  |---------------------------------------------------|
1 | =COUNTIFS(Rating,">=9",Rating,"<=10",Agent,"Bob") |
  |---------------------------------------------------|
2 | =COUNTIFS(Rating,">=6",Rating,"<=8",Agent,"Bob")  |
  |---------------------------------------------------|
3 | =COUNTIFS(Rating,">=0",Rating,"<=5",Agent,"Bob")  |
  |---------------------------------------------------|

不含命名范围的公式

           H
  |----------------------------------------------------------------|
1 | Bob                                                            | 
  |----------------------------------------------------------------| 
2 | =COUNTIFS($B$2:$B$9,">="&$D2,$B$2:$B$9,"<="&$E2,$A$2:$A$9,H$1) | 
  |----------------------------------------------------------------| 
3 | =COUNTIFS($B$2:$B$9,">="&$D3,$B$2:$B$9,"<="&$E3,$A$2:$A$9,H$1) | 
  |----------------------------------------------------------------| 
4 | =COUNTIFS($B$2:$B$9,">="&$D4,$B$2:$B$9,"<="&$E4,$A$2:$A$9,H$1) | 
  |----------------------------------------------------------------|

样本数据

      A        B
  |-------|--------|
1 | Agent | Rating |
  |-------|--------|
2 | Bob   | 4      |
  |-------|--------|
3 | Bob   | 5      |
  |-------|--------|
4 | Bob   | 10     |
  |-------|--------|
5 | John  | 6      |
  |-------|--------|
6 | Bob   | 10     |
  |-------|--------|
7 | John  | 5      |
  |-------|--------|
8 | Bob   | 3      |
  |-------|--------|
9 | John  | 4      |
  |-------|--------|

计算

     D     E    F      G         H     I
  |-----|-----|---|-----------|-----|------|
1 | Min | Max |   |           | Bob | John |
  |-----|-----|---|-----------|-----|------|
2 | 9   | 10  |   | Positive: | 2   | 0    |
  |-----|-----|---|-----------|-----|------|
3 | 6   | 8   |   | Neutral:  | 0   | 1    |
  |-----|-----|---|-----------|-----|------|
5 | 0   | 5   |   | Poor:     | 3   | 2    |
  |-----|-----|---|-----------|-----|------|

相关内容