☰

Excel - 比较特定日期和时间

tag-icon • tag-icon microsoft-excel
Excel - 比较特定日期和时间

我正在尝试创建一个包含一列的跟踪器来检查我们是否已满足 SLA。

Column A - Date Received
Column B - Time Received
Column C - Date and Time Combined (A2+B2)
Column D - Date Resolved
Column E - Time Resolved
Column F - Date and Time Resolved (D2+E2)

本质上我需要检查的是：

如果收到日期（A 列）和收到时间（B 列）都在中午 12 点之后，则解决日期（D 列）应为下一个工作日中午 12 点（E 列）。

例如：7 月 31 日星期一下午 2 点收到请求，8 月 1 日星期二上午 11 点解决 -> 满足 SLA

例如：7 月 31 日星期一下午 2 点收到请求，8 月 1 日星期二下午 3 点解决 -> 未满足 SLA

我不知道如何组合日期和时间数据以插入公式。我尝试组合日期和时间，如上所示：

=IF(AND(O2="Team Inbox", C2 >= TIME(12,0,0)), NETWORKDAYS(A2,E2,Holidays[2023Holidays])<=2, G2  <= TIME(12,0,0)), "Yes", "No")

Column O = Specific Inbox

[2023Holidays] = Table of holidays for business

任何帮助，将不胜感激！

答案1

OP 中的公式括号不匹配 - 有 5 个左括号和 6 个右括号。考虑到公式的结构，可以合理地假设存在虚假的右括号，并且该AND函数旨在满足四个条件：

  • O2="Team Inbox"
  • B2>=TIME(12,0,0)注意C2OP 中的 (日期+时间) 在B2此处更正为 (时间)
  • NETWORKDAYS(A2,E2,...)<=2
  • G2<=TIME(12,0,0)

必须满足所有 4 个条件，公式才会得出“是”的结论，否则结果为“否”。

这看起来有点奇怪。特别是团队收件箱的条件和收到的时间。

在绩效衡量方面，似乎可能会有以下值得关注的数量

  • 收到的票总数
  • 通过团队收件箱收到的邮件总数的子集，其中
  • 在期限内解决的总数
  • 未在期限内解决的总数

除了简单的“是”/“否”结果之外，似乎有可能（很可能？）存在一个适用于未通过团队收件箱收到的票证的附加结果（否则为什么要针对每张票证记录特定收件箱，以及为什么 OP 要使用这些数据？）。

此外，OP 表示目标是在下一个工作日中午 12 点之前解决中午 12 点之后收到的票证（？）。未说明的目标是中午 12 点之前收到的票证。OP 中的公式对此类票证给出“否”似乎很奇怪，我怀疑这不是预期的。

中午 12 点之前收到的票有两种可能：

  1. 这些票与未通过团队收件箱收到的票（即无需说明是否达到目标）归为一类，或
  2. 目标是在收到票的同一个工作日解决问题。

对于情况 1：

  =IF (
       OR  (
            O2<>"Team Inbox",
            B2<TIME(12,0,0)
           ),
       "-",
       IF  (
            AND (
                 E2<=TIME(12,0,0),
                 NETWORKDAYS(A2,D2)<=2
                ),
            "Yes",
            "No"
           )
      )

结果是：

  • "-"当不是Specific Inbox或Team Inbox收到的时间是在中午之前时，否则就是
  • "Yes"当满足下一个工作日中午完成期限的目标时，
  • "No"当未能满足下一个工作日中午完成期限的目标时

对于情况 2：

=IF (O2 <> "Team Inbox",
     "-",
     IF  (B2<TIME(12,0,0),
          IF  (NETWORKDAYS(A2,D2)<=1,
               "Yes",
               "No"
              ),
          IF  (
               AND (
                    E2<=TIME(12,0,0),
                    NETWORKDAYS(A2,D2)<=2
                   ),
               "Yes",
               "No"
              )
         )
    )

本案的结果是：

  • "-"当Specific Inbox不是时Team Inbox，否则就是
  • "Yes"中午 12 点前收到工单，且满足当天完成的目标
  • "Yes"中午 12 点后收到工单，且满足下一个工作日完成的目标
  • "No"当目标完成度未达到时。

上述两个案例可能不能准确表达原作者的意图。但它们应该强调分析情况和识别所有规则和案例作为解决过程的一部分的重要性。

相关内容