☰

应用“立即自动套用格式” Word 脚注

tag-icon • tag-icon microsoft-word
应用“立即自动套用格式” Word 脚注

我的团队成员每周都会处理 Word 文档中含有大约 300 个脚注链接的文档。通常我们通过右键单击并与对话框交互来手动添加它们。

我发现了自动套用格式，并且可以将其添加到快速访问工具栏。是的，我已经看过这篇文章了：如何在 Microsoft WORD for MAC 中激活自动套用格式以同时激活多个超链接。

这很好，但它不会格式化我的脚注文本。它会更改正文中的链接，但不会更改脚注。

我在使用 Mac，非常感激任何帮助。

答案1

您说得对，这不适用于脚注。但您可以使用 VBA 宏，将每个脚注的文本复制到一个空文档，自动格式化，然后再复制回来。这是 Graham Mayor 编写的代码的变体（http://www.vbaexpress.com/forum/showthread.php?52466-applying-hyperlink-styles-in-footnotes-and-endnotes）将会起作用：

Sub LinkNotes()
Dim oDoc As Document
Dim oTemp As Document
Dim oNote As Range
Dim oFN As Footnote
Dim oRng As Range
Set oDoc = ActiveDocument
oDoc.Save
Set oTemp = Documents.Add(Template:=oDoc.FullName, Visible:=False)

For Each oFN In oDoc.Footnotes
    Set oNote = oFN.Range
    Set oRng = oTemp.Range
    oRng.FormattedText = oNote.FormattedText
    oRng.Style = "Footnote Text"
    Options.AutoFormatReplaceHyperlinks = True
    oRng.AutoFormat
    oRng.End = oRng.End - 1
    oNote.FormattedText = oRng.FormattedText
Next oFN
    
oTemp.Close savechanges:=wdDoNotSaveChanges
Set oFN = Nothing
Set oDoc = Nothing
Set oTemp = Nothing
Set oRng = Nothing
Set oNote = Nothing
End Sub

相关内容