☰

awk 对列中的值进行插值

tag-icon • tag-icon text-processing awk
awk 对列中的值进行插值

我遇到了 looong txt 文件的问题，我有这个例子：

542    701.00
789    
971    703.00
123    708.00
879    
785    
974
101    716.00

我需要将 $2 列中的缺失值替换为缺失值附近顶部值和底部值之间的插值，我没有尝试任何操作，因为我真的不知道如何开始！有人可以帮我吗？谢谢

输出

542    701.00
789    702.00
971    703.00
123    708.00
879    710.00
785    712.00
974    714.00
101    716.00

答案1

如果插值应该以相等的间隔间隔，那么可以这样做：

awk '
  NF > 1 {
    if(i++){ d=($2-s)/i; for(j=1; j<i; j++) printf "%s\t%.2f\n", a[j], s+j*d }
    s=$2; i=0; printf "%s\t%.2f\n", $1, $2
    next
  }
  { a[++i] = $1 }
' file

不，这不是“插值”的唯一方法。

答案2

awk '
  BEGIN {split("",A)}
  $2 == "" {
    A[length(A)] = $1
    # print $0, length(A)
  }
  $2 != "" {
    if (length(A) > 0) {
      I = ( $2 - P2 ) / (length(A) + 1)
      for(X=0; X<length(A); X++) {
        print "<" A[X] " "  (P2 + I * (X+1)) ">"
      }
      split("",A)
    }
    print  "!" $1 " " $2 "!"
    P1=$1; P2=$2
  }
  END {}
'

给出

!542 701.00!
<789 702>
!971 703.00!
!123 708.00!
<879 710>
<785 712>
<974 714>
!101 716.00!

相关内容