☰

这个批次代码有什么问题？

tag-icon • tag-icon batch
这个批次代码有什么问题？

有人能帮忙找出这段代码的错误吗？基本上，这只是我为修复某些问题而编写的脚本的一部分，我得到的结果是“DCHP Status”给出空白结果或无效答案，例如 dhcp lan 显示 NO。我无法在某些机器上使用 powershell，因此需要使用批处理。

基本上，代码使用 psexec 连接局域网上的远程计算机并基于 DHCP 或静态 IP 运行脚本并修复某些问题，以便我使用 sccm remote 正确连接。

@echo off
setlocal enabledelayedexpansion

:: Disabling UAC
echo Disabling UAC
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "EnableLUA" /t REG_DWORD /d 0 /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "ConsentPromptBehaviorAdmin" /t REG_DWORD /d 0 /f >nul

:: Listing all network adapters
echo List all network adapters
netsh interface show interface
echo.

:: Getting the name of the network adapters
echo Enter the interface name you want to fix:
set /p adapterName=

:: Validating the user input
if not defined adapterName (
    echo You must enter a network adapter name!
    exit /b
)

:: Running ipconfig and storing the output in a temporary file
echo Run ipconfig and store the output in a temporary file
ipconfig > ipconfig.txt
REM ipconfig /all > dhcp.txt
netsh interface ip show addresses name="%adapterName%" > dhcp.txt

:: Parsing the IP address, subnet mask, and default gateway from the output
for /f "tokens=2 delims=:" %%A in ('findstr /i /c:"IPv4 Address" ipconfig.txt') do (
    set "ip=%%A"
    set "ip=!ip: =!"
)

for /f "tokens=2 delims=:" %%B in ('findstr /i /c:"Subnet Mask" ipconfig.txt') do (
    set "mask=%%B"
    set "mask=!mask: =!"
)

for /f "tokens=2 delims=:" %%C in ('findstr /i /c:"Default Gateway" ipconfig.txt') do (
    set "gateway=%%C"
    set "gateway=!gateway: =!"
)

for /f "tokens=2 delims=:" %%D in ('findstr /i /b /c:"DHCP Enabled" dhcp.txt') do (
    set "DHCP=%%D"
    set "DHCP=!DHCP: =!"
    if /i "!DHCP!"=="Yes" (
        set "DHCPStatus=Yes"
    ) else (
        set "DHCPStatus=No"
    )
)

if /i "%DHCPStatus%"=="Yes" (
    goto :dhcp
) else (
    goto :static
)

:dhcp
echo.
echo Actual network configuration of host
echo IP Address: !ip!
echo Subnet Mask: !mask!
echo Default Gateway: !gateway!
echo DHCP: !DHCPStatus!
echo.

:static
echo.
echo Actual network configuration of host
echo IP Address: !ip!
echo Subnet Mask: !mask!
echo Default Gateway: !gateway!
echo DHCP: !DHCPStatus!
echo.

错误

全部代码：

@echo off && setlocal enabledelayedexpansion

set "_xptoKey=HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters"
set "_ipv6Key=HKLM\SYSTEM\CurrentControlSet\Services\Tcpip6\Parameters"
set "_UACKey=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System"

echo/Disabling UAC & for %%i in =;( EnableLUA,ConsentPromptBehaviorAdmin 
    );= do >nul reg add "!_UACKey!" /v "%%~i" /t REG_DWORD /d 0 /f

:: Listing all network adapters interfaces
echo/List all network adapters & netsh interface show interface

:: Getting the name of the network adapters and validating the user input
echo/ & set /p "_adapterName=Enter the interface name you want to fix: " || =;(
     echo You must enter a network adapter name! & exit /b );=

:: Parsing the IP address, subnet mask, and default gateway from the output
for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"IPv4"
    ');= do set "_ip=%%~B" && call set "_ip=%%_ip: =%%"

for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"Sub"
    ');= do set "_Sub=%%~B" && call set "_Sub=%%_Sub: =%%"
    
for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"Gate"
    ');= do set "_Gate=%%~B" && call set "_Gate=%%_Gate: =%%"

:: Showing the current settings obtained
echo/Actual Network Configuration of Host
echo/     IP Address: !_ip!
echo/    Subnet Mask: !_sub!
echo/Default Gateway: !_gate!
echo/           DHCP: !_dhcp! & echo/ 

:: Applying configurations and executing common commands
echo/Disabling & =;( 
     echo/Disabling network adapter... Please Wait... >con
     netsh interface set interface "Wi-Fi" disable 
     timeout /nobreak 6 | echo/ Enabling network adapter... Please wait... >con
     netsh interface set interface "Wi-Fi" enable
     timeout /nobreak 6 | echo/ >con 
    );= >nul 2>&1

:: Set the IP address, subnet mask, gateway, DNS servers if the current IP is not static
netsh interface ip show addresses name="!_adapterName!" | findstr "DHCP.*Yes" >nul || =;(
     echo/Configuring the network settings...
     netsh interface ipv4 set address name="!_adapterName!" source=static address="!_ip!" mask="!_sub!" gateway="!_gate!"
     netsh interface ipv4 set dns name="!_adapterName!" static 1.1.1.1 validate=no
     netsh interface ipv4 add dns name="!_adapterName!" 1.0.0.1 index=2 validate=no
     netsh interface ipv4 delete dnsservers name="!_adapterName!" 1.2.3.4 validate=no
    );=

echo/Adding DNS sufix: [xpto.pt + xpto2.pt] 
reg add "!_xptoKey!" /f /v SearchList /t REG_SZ /d "xpto.pt,xpto2.pt" >nul

echo/Disable TCP/IP v6 for the network adapter...
reg add "!_ipv6Key!" /v "DisabledComponents" /t REG_DWORD /d 0xffffffff /f >nul

for %%i in =;( "set global randomizeidentifier=disabled","isatap set state state=disabled",
     "6to4 set state state=disabled","set privacy state=disable","set teredo disable"
    );= do netsh interface IPV6 %%~i 

echo/Testing Network Connection (DHCP^)...
ping -n 4 10.0.25.80 | findstr "ms loss" | sort /Uniq

echo/Running Flushdns and Registerdns... & >nul =;( 
     ipconfig /flushdns & ipconfig /registerdns 
    );= 2>&1 | findstr "IP Cache" | Sort /Uniq

timeout /nobreak 5 | endlocal & goto :eof

答案1

您不需要创建临时文件，也不必在操作它们之后删除它们以获得所需的结果，您可以使用双for循环直接从命令输出中获取字符串，同时观察标签:static基本上与标签相同，因此您可以在没有标签的情况下:DHCP使用...echo variables:specific:each

@echo off && setlocal enabledelayedexpansion

set "_xptoKey=HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters"
set "_UACKey=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System"

echo/Disabling UAC & for %%i in =;( EnableLUA,ConsentPromptBehaviorAdmin 
    );= do >nul reg add "!_UACKey!" /v "%%~i" /t REG_DWORD /d 0 /f
    
echo/List all network adapters & netsh interface show interface & echo/

:: Getting the name of the network adapters and validating the user input
echo/ & set /p "_adapterName=Enter the interface name you want to fix: " || =;(
     echo You must enter a network adapter name! & exit /b );=

:: Parsing the IP address, subnet mask, and default gateway from the output    
for %%G in =;( IPv4,Sub,Gate );= do for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| Find "%%~G" ');= do set "_%%~G=%%~B" && call set "_%%~G=%%_%%~G: =%%"

:: Showing the current settings obtained
echo/ & echo/Actual network configuration of host
echo/     IP Address: !_IPv4! &  echo/    Subnet Mask: !_Sub!
echo/Default Gateway: !_Gate! &  echo/           DHCP: !_DHCP! & echo/ 

:: Applying configurations and executing common commands
echo/Disabling & =;( 
     echo/Disabling network adapter... Please Wait... >con
     netsh interface set interface "Wi-Fi" disable 
     timeout /nobreak 6 | echo/ Enabling network adapter... Please wait... >con
     netsh interface set interface "Wi-Fi" enable
     timeout /nobreak 6 | echo/ >con 
    );= >nul 2>&1

:: Set the IP address, subnet mask, gateway, DNS servers if the current IP is not static
netsh interface ip show addresses name="!_adapterName!" | findstr "DHCP.*Yes" >nul || =;(
     echo/Configuring the network settings...
     netsh interface ipv4 set address name="!_adapterName!" source=static address="!_ip!" mask="!_sub!" gateway="!_gate!"
     netsh interface ipv4 set dns name="!_adapterName!" static 1.1.1.1 validate=no
     netsh interface ipv4 add dns name="!_adapterName!" 1.0.0.1 index=2 validate=no
     netsh interface ipv4 delete dnsservers name="!_adapterName!" 1.2.3.4 validate=no
    );=

>nul =;(
     echo/Adding DNS sufix: [xpto.pt + xpto2.pt] >con:
     echo/reg add "!_xptoKey!" /f /v SearchList /t REG_SZ /d "xpto.pt,xpto2.pt" 
    
     echo/Disable TCP/IP v6 for the network adapter... >con:
     echo/reg add "!_xptoKey:p\=p6\!" /v "DisabledComponents" /t REG_DWORD /d 0xffffffff /f 
    );= 2>&1

for %%i in =;( "set global randomizeidentifier=disabled","isatap set state state=disabled",
     "6to4 set state state=disabled","set privacy state=disable","set teredo disable"
    );= do netsh interface IPV6 %%~i 

echo/Testing Network Connection (DHCP^)...
ping -n 4 10.0.25.80 | findstr "ms loss" | sort /Uniq

echo/Running /Flushdns and /RegisterDNS... & >nul =;( 
     ipconfig /flushdns & ipconfig /registerdns 
    );= 2>&1 | findstr "IP Cache" | Sort /Uniq

timeout /nobreak 5 | endlocal & goto :eof
  • 或者与原始代码最接近的替代方案......

@echo off && setlocal enabledelayedexpansion

echo/Disabling UAC & for %%i in =;( EnableLUA,ConsentPromptBehaviorAdmin 
    );= do >nul reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v "%%~i" /t REG_DWORD /d 0 /f

:: Listing all network adapters
echo/List all network adapters & netsh interface show interface

:: Getting the name of the network adapters and validating the user input
echo/ & set /p "_adapterName=Enter the interface name you want to fix: " || =;(
     echo You must enter a network adapter name! & exit /b );=

:: Parsing the IP address, subnet mask, and default gateway from the output
for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"IPv4"
    ');= do set "_ip=%%~B" && call set "_ip=%%_ip: =%%"

for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"Sub"
    ');= do set "_Sub=%%~B" && call set "_Sub=%%_Sub: =%%"
    
for /f "tokens=1-2 delims=:(" %%A in =;('
     ipconfig /all ^| findstr /ic:"Gate"
    ');= do set "_Gate=%%~B" && call set "_Gate=%%_Gate: =%%"

netsh interface ip show addresses name="%_adapterName%" | findstr "DHCP.*Yes" >nul && =;(
    set "_dhcp=Yes" && goto :dhcp );= || set "_dhcp=No" && goto :static

:dhcp
echo/
echo/Actual network configuration of host
echo/     IP Address: !_ip!
echo/    Subnet Mask: !_sub!
echo/Default Gateway: !_gate!
echo/           DHCP: !_dhcp! & echo/ 
endlocal & goto :eof

:static
echo/
echo/Actual network configuration of host
echo/     IP Address: !_ip!
echo/    Subnet Mask: !_sub!
echo/Default Gateway: !_gate!
echo/           DHCP: !_dhcp!
echo/           DHCP: !_dhcp! & echo/ 
endlocal & goto :eof

请注意，您当前正在执行一个命令，该命令重定向输出并将此输出提交到文件以进行循环操作，并检查行中是否有是/否来定义此变量并将执行带到流控制（goto :DHCP或goto :static标签），但一行即可完成此操作，而不需要上述所有步骤。

findstr查看在命令的一行/输出 ( ) 中搜索多个字符串的条件的用法，findstr String1.*String2并将其重定向到运算符，该运算符将根据结果是 true/success ( &&) 还是 false/failure ( ||) 来直接定义变量：

如果在同一行上找到字符串DHCP+ 一个或多个字符（.*） +则返回，接下来的执行将是 之后的操作，但如果执行返回，则在同一行上找不到多个字符串，运算符：Yestrue&& (executes these commands)false|| (execute this block)

netsh interface ip show addresses name="%_adapterName%" | findstr "DHCP.*Yes" >nul && =;(
    set "_dhcp=Yes" && goto :dhcp );= || set "_dhcp=No" && goto :static

Endlocal最后，使用时务必考虑添加Setlocal，特别是如果要多次执行同一条命令而不关闭当前会话时。

附言：： 考虑DavidPostill♦ 的回答/B，他的未定义变量的核心是在你的findstr...命令中使用。

其他资源：

答案2

“DCHP 状态”给出空白结果

findstr /i /b /c:"DHCP Enabled" dhcp.txt按书写方式损坏。

  • /b如果位于行的开头，则匹配模式。
  • /c:"string"使用字符串作为文字搜索字符串（可能包含空格）。

然而：

要匹配整个短语/句子或使用正则表达式，请使用/C 和 /R选项。

（重点是我的）

因此你需要删除/b 或者添加/r。

删除/b对我有用的东西：

F:\test>type dhcp.txt

Configuration for interface "Wireless Network Connection"
    DHCP enabled:                         Yes
    IP Address:                           192.168.188.250
    Subnet Prefix:                        192.168.188.0/24 (mask 255.255.255.0)
    Default Gateway:                      192.168.188.251
    Gateway Metric:                       0
    InterfaceMetric:                      25


F:\test>findstr /i /c:"DHCP Enabled" dhcp.txt
    DHCP enabled:                         Yes

F:\test>

您还需要for按如下方式更改循环：

F:\test>type test.cmd
@echo off
setlocal enabledelayedexpansion
for /f "tokens=3" %%D in ('findstr /i /c:"DHCP Enabled" dhcp.txt') do (
    if /i "%%D"=="Yes" (
        set "DHCPStatus=Yes"
    ) else (
        set "DHCPStatus=No"
    )
    echo !DHCPStatus!
  )
endlocal

F:\test>test
Yes

F:\test>

进一步阅读

答案3

您的问题是如何使用 delims，...即，您可以看到；

/B         Matches pattern if at the beginning of a line.

但你必须“尊重”你自己的产出并真正去做；

for /f "tokens=2 delims=:" %%D in ('findstr /i /b /c:"    DHCP enabled" dhcp.txt') do (

PS：这个也能正常工作；

for /f "tokens=2 delims=:" %%D in ('findstr /i /b /c:"    DHCP enabled" dhcp.txt') do (
    set "DHCPStatus=%%D"
)

相关内容