☰

我怎样才能将这些数据放在单独的列中

tag-icon • tag-icon bash text-processing
我怎样才能将这些数据放在单独的列中 
Frequencies -- 1403.6738 1403.6738 1403.6738
IR Inten -- 25.0809 25.0809 25.0809

我想要两列

Frequencies     IR Inten
1403.6738       25.0809

等等

答案1

使用 Raku（以前称为 Perl6 的编程语言）

Raku 有一个巧妙的Z运算符来解决此类问题，可以“压缩”项目，每个列表中都有一个：

~$ raku -e 'my @array1 = lines(); put ( [Z] @array1[0].words, @array1[1].words).join("\n");'  Freq_IR.txt
Frequencies IR_Inten
-- --
1403.6738 25.0809
1403.6738 25.0809
1403.6738 25.0809

注意：我必须更正上面的标题行，以便第二列的标题为“ IR_Inten”。在使用上面的代码重新排列数据之前，您可以手动编辑或运行下面的代码：

~$ raku -pe 's/IR \s Inten/IR_Inten/;'  Freq_IR.txt > Freq_IR2.txt

HTH。

https://raku.org
https://docs.raku.org/language/operators#Zip_metaoperator
https://docs.raku.org/language/operators#index-entry-[+]_(reduction_metaoperators)

答案2

在每个 Unix 机器上的任何 shell 中使用任何 awk：

$ awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END { print hdr[1], hdr[2]; for (i=1; i<=n; i++) print vals[1,i], vals[2,i] }
' file
Frequencies     IR Inten
1403.6738       25.0809
1403.6738       25.0809
1403.6738       25.0809

并适用于任意数量的输出行和列：

awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END {
        for (c=1; c<=NR; c++) {
            printf "%s%s", hdr[c], (c<NR ? OFS : ORS)
        }
        for (r=1; r<=n; r++) {
            for (c=1; c<=NR; c++) {
                printf "%s%s", vals[c,r], (c<NR ? OFS : ORS)
            }
        }
    }
' file

答案3

使用 awk 我们可以进行数据转换。

awk -F ' -- ' '
{
  # populate the array
  a[++N] = $1; split($2, t, " ")
  for (k in t) { a[++N] = t[k] }
}
END {ORS = ""
  for (c=i=1; i<=N/NR; i++) {
    for (j=i; j<=N; j+=N/NR) {
      print a[j] (c++%NR ? "\t" : "\n")
    }
  }
}
' file
Frequencies IR Inten
1403.6738   25.0809
1403.6738   25.0809
1403.6738   25.0809

基本思想是首先填充数组并在末尾记录数组的长度。然后将数组分成 N/NR 个部分，并从每个部分中选取相应的元素。在 Python 等其他语言中，此操作称为zip。

相关内容