从 ifconfig 中提取接口名称、硬件地址和 IP 地址（必须使用 ifconfig 而不是 ip 命令）

Question 1

awk 'BEGIN { OFS="\t" }; # use tab for output separator

     ! /^ / {   # line doesnt begin with a space, must be an interface line, extract it
       i=gensub(/:$/,"",1,$1)
       mac[i]=$5;     # this will either be a HWAddr or empty
       ifaces[i]=1
     };

     /^ +inet/ { ip[i] = ip[i] " " gensub(/addr:/,"",1,$2) };

     /^ +ether/ { mac[i]=$2};  # this will only match if there WASNT a HWAddr on the iface line

     END {
       for (i in ifaces) {
         sub(/^ +/,"",ip[i]); # remove unwanted space from beginning of ip addresses
         #if (ip[i]  == "") ip[i]  = "--"; #optional
         #if (mac[i] == "") mac[i] = "--"; #optional
         print i, ip[i], mac[i]
       }
     }' filename | sort

（或者只是通过管道输入ifconfig而不是给它一个输入文件名）

此 awk 脚本可以处理任一ifconfig输出变体，并输出三个制表符分隔的字段：接口名称、IP 地址和 MAC 地址。

如果第二字段中有多个 IP 地址，则它们之间用空格分隔。

针对 input1 运行并通过管道传输到时的输出sort：

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1

针对 input2 运行并通过管道传输到时的输出sort：

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0            00:50:56:00:00:00
eth1            00:50:56:00:00:00
lo      127.0.0.1

注意：您请求的输出将 192.168.0.2 作为 bond0:0 的 IP 地址，但您的示例数据具有 192.168.0.1，与接口相同bond0。

如果取消注释脚本中的“可选”行，它将确保始终有 3 个制表符分隔的输出字段，即使 IP 地址或 MAC 地址字段为空。

输出如下：

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1       --

和

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0    --      00:50:56:00:00:00
eth1    --      00:50:56:00:00:00
lo      127.0.0.1       --

补充评论：

它是一个错误忽略该ip命令。它多年来一直是 Linux 上的标准，许多向接口添加辅助/备用/“别名”IP 地址的程序都会使用它。以这种方式添加到接口的辅助 IP 地址将仅有的显示为，运行ip addr show时它们不会显示。ifconfig

ifconfig应该仅被视为遗留，至少在 Linux 上是这样。

Answer

awk 'BEGIN { OFS="\t" }; # use tab for output separator

     ! /^ / {   # line doesnt begin with a space, must be an interface line, extract it
       i=gensub(/:$/,"",1,$1)
       mac[i]=$5;     # this will either be a HWAddr or empty
       ifaces[i]=1
     };

     /^ +inet/ { ip[i] = ip[i] " " gensub(/addr:/,"",1,$2) };

     /^ +ether/ { mac[i]=$2};  # this will only match if there WASNT a HWAddr on the iface line

     END {
       for (i in ifaces) {
         sub(/^ +/,"",ip[i]); # remove unwanted space from beginning of ip addresses
         #if (ip[i]  == "") ip[i]  = "--"; #optional
         #if (mac[i] == "") mac[i] = "--"; #optional
         print i, ip[i], mac[i]
       }
     }' filename | sort