☰

类似“粘贴”但在分隔符后垂直对齐的东西？

tag-icon • tag-icon text-processing
类似“粘贴”但在分隔符后垂直对齐的东西？

我想将两个文件粘贴在一起，但在节分隔符行之后垂直对齐::。这就是我的意思。

内容file1：

Apple
Banana
Carrot
::
Durian

内容file2：

Energy
Flight
::
Gravity
Heartbreak

期望的输出：

Apple Energy
Banana Flight
Carrot 
::
Durian Gravity
 Heartbreak

到目前为止我知道paste会几乎做我想做的事（没有很好的垂直对齐）；另一种选择是将file1和拆分file2为多个文件，然后将结果连接在一起，但我想如果可以的话避免这种情况。我怎样才能做到这一点？

我并不严格需要使用paste.任何有效的方法都有效！

答案1

使用任何 awk：

$ cat tst.awk
BEGIN {
    blockSep = "::"
}
FNR == 1 {
    numBlocks[++fileNr] = 0
}
(FNR == 1) || ($0 == blockSep) {
    numLines[fileNr,++numBlocks[fileNr]] = 0
}
$0 != blockSep {
    vals[fileNr,numBlocks[fileNr],++numLines[fileNr,numBlocks[fileNr]]] = $0
}
END {
    maxBlocks = ( numBlocks[1] > numBlocks[2] ? numBlocks[1] : numBlocks[2] )
    for ( blockNr=1; blockNr<=maxBlocks; blockNr++ ) {
        maxLines = ( numLines[1,blockNr] > numLines[2,blockNr] ? numLines[1,blockNr] : numLines[2,blockNr] )
        for ( lineNr=1; lineNr<=maxLines; lineNr++ ) {
            print vals[1,blockNr,lineNr], vals[2,blockNr,lineNr]
        }
        if ( blockNr < maxBlocks ) {
            print blockSep
        }
    }
}


$ awk -f tst.awk file1 file2
Apple Energy
Banana Flight
Carrot
::
Durian Gravity
 Heartbreak

答案2

这是一极其黑客解决方案适用于您的示例数据，因为这两个文件只有::共同的行，并且文件只包含单个单词（没有空格）。因此，我认为它非常脆弱，而且根本不通用。

它解析并排输出diff，因此它diff是垂直对齐的。

$ diff -y file1 file2 | awk -v OFS='\t' 'NF == 3 { print $1, $3; next } $2 == "<" { print $1; next } $1 == ">" { print "", $2; next } { print $1 }'
Apple   Energy
Banana  Flight
Carrot
::
Durian  Gravity
        Heartbreak

awk解析输出的代码根据diff -y字段数量和数据某些部分的内容输出每行的选定部分。

相关内容