☰

如何彻底关闭 WLBS 上的所有连接

tag-icon • tag-icon iis web-server wlbs
如何彻底关闭 WLBS 上的所有连接

我在 Windows 2000 中使用 WLBS 为 2 个 Web 服务器提供冗余和负载平衡。当我想关闭其中一个服务时，我会从命令行使用“WLBS dripstop”。但是，从监控 IIS 中打开的连接数来看，关闭现有连接需要很长时间。如果我运行“WLBS stop”，剩余的连接将挂起几分钟，因为它们会发现连接的另一端不再存在。我们不需要长时间运行的连接，页面请求会在 10 秒内返回。WLBS 或 IIS 是否有某种方法可以关闭任何打开的非活动连接，以便我可以从负载平衡中删除服务器，而无需等待所有打开的连接自行关闭？

答案1

使用Joel 讨论组的一个老把戏关闭 keep-alive，然后运行 ​​WLBS dripstop 是让其正常工作的关键。然后我在 VBS 中编写了一个脚本来自动化整个过程。有两个脚本。一个脚本用于从集群中删除节点，另一个脚本用于使节点重新联机。

删除脚本如下。

Set IISOBJ = getObject("IIS://LocalHost/W3SVC")
Dim IISInstance
Dim FoundIIS
Dim IISInstanceName 
Dim NumConnections
Dim WSHShell
Set WSHShell = WScript.CreateObject("WScript.Shell")

IISInstanceName = "Default Web Site"

FoundIIS = False

For each IISInstance in IISOBJ
    If (IISInstance.Class = "IIsWebServer") Then
        If (IISInstance.ServerComment = IISInstanceName) Then
            IISInstance.Put "AllowKeepAlive", False
            IISInstance.SetInfo()
            FoundIIS = True
            Exit For
        End If
    End If
Next

If Not FoundIIS Then
    WScript.Echo "Could Not Find IIS.  Exiting."
    Wscript.quit()
End If

WSHShell.Run "wlbs drainstop" , 0, true

WScript.Echo " Going To Sleep For: " & IISInstance.Get("ConnectionTimeout") & " Seconds"

WScript.Sleep IISInstance.Get("ConnectionTimeout") * 1000 

WSHShell.Run "wlbs stop" , 0, true

WScript.Echo "Successfully removed node from load balancing"

使机器重新上线的脚本如下。

Set IISOBJ = getObject("IIS://LocalHost/W3SVC")
Dim IISInstance
Dim FoundIIS
Dim IISInstanceName 

IISInstanceName = "Default Web Site"

FoundIIS = False

For each IISInstance in IISOBJ
    If (IISInstance.Class = "IIsWebServer") Then
        If (IISInstance.ServerComment = IISInstanceName) Then
            IISInstance.Put "AllowKeepAlive", True
            IISInstance.SetInfo()
            FoundIIS = True
            Exit For
        End If
        End If
Next

If Not FoundIIS Then
    WScript.Echo "Could Not Find IIS.  Exiting."
    Wscript.quit()
End If

Dim WSHShell
Set WSHShell = WScript.CreateObject("WScript.Shell")

WSHShell.Run "wlbs start" , 0, true

WScript.Echo "Successfully added node to load balancing"

您可以更改脚本顶部的 IISInstanceName 变量以匹配您的 Web 服务器的名称。这是您转到“管理工具”下的“Internet 信息服务”部分时显示的名称。您可以将其更改为您为 Web 服务器命名的任何名称。总的来说，这有点笨拙，但它有效。也可以将第一行更改为

Set IISInstance = getObject("IIS://LocalHost/W3SVC/1")

然后切掉按名称查找服务器的整个 for 循环，但我认为按名称而不是按某个数字查找服务器更“正确”，我不确定在添加和删除 Web 服务器实例等情况下 Windows 是否会发生变化。

答案2

只需将保持连接超时时间从两分钟降低至约 20 秒就足够了。

http://www.microsoft.com/technet/prodtechnol/WindowsServer2003/Library/IIS/ea116535-8eb9-4c80-8b14-b34418dbfe42.mspx

相关内容