☰

如何配置工作组以从 WSUS 接收更新

tag-icon • tag-icon windows-server-2003 windows-xp wsus workgroup
如何配置工作组以从 WSUS 接收更新

大家好，我有 WSUS 服务器，并且活动目录运行良好。但是，如何将运行 Windows XP 的工作组电脑连接到 WSUS，而不将它们加入 AD？提前谢谢大家。

答案1

我使用以下批处理脚本来打开和关闭 WSUS 系统。在我们分发格式化的系统之前，它可以快速更新它们，效果非常好。

将该部分下的 [SERVER] 更改为您的 WSUS 服务器:USEWSUS。


@echo off
:START
cls
echo Temporary WSUS Script
echo ==============================
echo This script will flip between using the internal WSUS server and Microsoft's servers.
echo.
set /p WSUSSETTING=Type [W] to use WSUS or [C] to clear the setting and use MS servers: 

IF /i (%WSUSSETTING%) == (W) goto CONTINUE
if /i (%WSUSSETTING%) == (C) goto CONTINUE

echo.
echo Error: Invalid selection
pause
goto START

:CONTINUE
echo Stopping Update Services...
net stop wuauserv
echo Deleting timeout registry entries (Safe to ignore errors)...
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v DetectionStartTime /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v NextDetectionTime /f

IF /i (%WSUSSETTING%) == (W) goto USEWSUS
IF /i (%WSUSSETTING%) == (C) goto USEMS

:USEWSUS
echo Changing update server to local WSUS server...
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v NoAutoUpdate /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AUOptions /t REG_DWORD /d 3 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AutoInstallMinorUpdate /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /t REG_DWORD /d 1 /f
goto COMPLETE

:USEMS
echo Clearing WSUS update server...
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /f
goto COMPLETE


:COMPLETE
echo Starting Update Services...
net start wuauserv

:END
echo ---
echo Complete.
pause

答案2

您可以通过直接更新注册表来进行相同的更改；快速搜索让我找到了这个关联看起来它包含正确的信息。如果不是，你再仔细搜索一下，就有可能找到你遗漏的信息。

答案3

如果是专业版，也可以使用本地组策略。运行gpedit.msc并浏览到“计算机配置 -> 管理模板 -> Windows 组件 -> Windows 更新”。

相关内容