☰

别名 do=... 后 zsh 解析错误

tag-icon • tag-icon zsh alias
别名 do=... 后 zsh 解析错误

.zshrc我的主目录中有以下文件：

# modify the prompt to contain git branch name if applicable
git_prompt_info() {
  current_branch=$(git current-branch 2> /dev/null)
  if [[ -n $current_branch ]]; then
    echo " %{$fg_bold[green]%}$current_branch%{$reset_color%}"
  fi
}
setopt promptsubst
export PS1='${SSH_CONNECTION+"%{$fg_bold[green]%}%n@%m:"}%{$fg_bold[blue]%}%c%{$reset_color%}$(git_prompt_info) %# '

# load our own completion functions
fpath=(~/.zsh/completion $fpath)

# completion
autoload -U compinit
compinit

# load custom executable functions
for function in ~/.zsh/functions/*; do
  source $function
done

# makes color constants available
autoload -U colors
colors

# enable colored output from ls, etc
export CLICOLOR=1

# history settings
setopt hist_ignore_all_dups inc_append_history
HISTFILE=~/.zhistory
HISTSIZE=4096
SAVEHIST=4096

# awesome cd movements from zshkit
setopt autocd autopushd pushdminus pushdsilent pushdtohome cdablevars
DIRSTACKSIZE=5

# Enable extended globbing
setopt extendedglob

# Allow [ or ] whereever you want
unsetopt nomatch

# vi mode
bindkey -v
bindkey "^F" vi-cmd-mode
bindkey jj vi-cmd-mode

# handy keybindings
bindkey "^A" beginning-of-line
bindkey "^E" end-of-line
bindkey "^R" history-incremental-search-backward
bindkey "^P" history-search-backward
bindkey "^Y" accept-and-hold
bindkey "^N" insert-last-word
bindkey -s "^T" "^[Isudo ^[A" # "t" for "toughguy"

# aliases
[[ -f ~/.aliases ]] && source ~/.aliases

# extra files in ~/.zsh/configs/pre , ~/.zsh/configs , and ~/.zsh/configs/post
# these are loaded first, second, and third, respectively.
_load_settings() {
  _dir="$1"
  if [ -d "$_dir" ]; then
    if [ -d "$_dir/pre" ]; then
      for config in "$_dir"/pre/**/*(N-.); do
        . $config
      done
    fi

    for config in "$_dir"/**/*(N-.); do
      case "$config" in
        "$_dir"/pre/*)
          :
          ;;
        "$_dir"/post/*)
          :
          ;;
        *)
          if [ -f $config ]; then
            . $config
          fi
          ;;
      esac
    done

    if [ -d "$_dir/post" ]; then
      for config in "$_dir"/post/**/*(N-.); do
        . $config
      done
    fi
  fi
}
_load_settings "$HOME/.zsh/configs"

# Local config
[[ -f ~/.zshrc.local ]] && source ~/.zshrc.local

不幸的是，当我启动终端时，出现以下错误：

/home/steven/.zshrc:72: parse error near `fi'

问题似乎出在我的别名文件中。我有两个别名文件：1. .aliases 2..aliases.local

.aliases已加载，其中包含以下要加载的命令.aliases.local：

[[ -f ~/.aliases.local ]] && source ~/.aliases.local

在我的.aliases.local文件中，我有以下两个别名：

alias server='ssh -p xxx [email protected]'
alias do='ssh -L xxxx:127.0.0.1:xxxx -N -f -l user -p xxxx xx.xx.xxx.xxx'

这些基本上是通过 ssh 进入我的服务器的别名（第一个别名），也是为了建立安全隧道，以便我可以使用 VNC 客户端连接到服务器。

这两个别名工作正常，但是当我在 中定义它们时.aliases.local，我不断收到此错误。我究竟做错了什么？

答案1

do是 shell 中的保留字。它是whileand循环语法的一部分for。当您将其定义为别名时，别名优先于保留字。因此，在别名扩展之后，shell 会看到：

if [ -d "$_dir/pre" ]; then
  for config in "$_dir"/pre/**/*(N-.); ssh -L xxxx:127.0.0.1:xxxx -N -f -l user -p xxxx xx.xx.xxx.xxx
    . $config
  done
fi

我不知道为什么 zsh 抱怨的是 thefi而不是分号后的 thedone或缺少do，但无论如何，这不是有效的语法。

您需要为别名选择一个不同的名称。避免全部保留字。

相关内容