☰

如何在不使用 SDK 的情况下查询 NetAPP ONTAP API？

tag-icon • tag-icon storage netapp
如何在不使用 SDK 的情况下查询 NetAPP ONTAP API？

我有一堆 NetApp 文件器，我一直通过ssh公钥-私钥对进行访问。

我想扩展我正在做的事情——我们反复遇到限制，例如ssh无法完成命令（执行前断开连接）并且我们正在运行的命令的输出格式是“人类可读的”，这意味着机器解析很烦人。

因此我想查询 API，并且出于各种原因，我想使用 CPAN 中的“现成”模块而不是 NetApp SDK 来进行查询。

这可以做到吗？如果可以，怎么做？

（我曾考虑过这是否更适合 Stack Overflow，但最终得出结论大概与系统管理员相比，perl 脚本更相关)。

答案1

基础非常简单——你需要复制两样东西：

  • XML
  • http（s）

从 CPAN 来看，有各种模块可以做到这一点。我喜欢LWP和XML::Twig。

情况是这样的：

#!/usr/local/bin/perl

use strict;
use warnings;

use XML::Twig;
use LWP::UserAgent;

my $filer     = 'filername';
my $vfiler    = 'vfilername';
my $user      = 'api-user';
my $pass      = 'api-pass';
my $api_call  = 'volume-list-info';
my %api_param = ( volume => 'vfiler_vol0' );

my $API = '/servlets/netapp.servlets.admin.XMLrequest_filer';
my $url = "https://$filer/$API";

my $xml_request = XML::Twig->new();
$xml_request->set_root(
    XML::Twig::Elt->new(
        'netapp',
        {   version => '1.7',
            vfiler  => $vfiler,
            xmlns   => 'http://www.netapp.com/filer/admin'
        },
    )
);
my $req = $xml_request->root->insert_new_elt($api_call);

foreach my $key ( keys %api_param ) {
    $req->insert_new_elt( $key, $api_param{$key} );
}

$xml_request->set_doctype('netapp SYSTEM "file:/etc/netapp_filer.dtd"');
$xml_request->set_xml_version('1.0');
$xml_request->set_encoding('utf-8');


my $agent = LWP::UserAgent->new(
    ssl_opts => {
        verify_hostname => 0,
        SSL_version     => 'SSLv3'
    }
);

my $request = HTTP::Request->new( POST => $url );
$request->content( $xml_request->sprint );
$request->authorization_basic( $user, $pass );

my $results = $agent->request($request);
if ( $results->is_success ) {

    #do nothing yet
}
else {
    print "Request error:", $results->status_line;
    die;
}
my $results_twig = XML::Twig->new( pretty_print => 'indented' );
$results_twig->parse( $results->content );

#dump the whole thing
$results_twig->print;

print some values selectively. 
foreach my $vol ( $results_twig -> root -> children('volume-info') ) {
    print $vol -> first_child_text('name'), " "; 
    print $vol -> first_child_text('state'),"\n";
}

相关内容