☰

对同一文件中的正则表达式进行着色

tag-icon • tag-icon sed text-processing regex
对同一文件中的正则表达式进行着色

我有一个大文件，需要查看某些模式。并且还根据第一个模式寻找另一个模式，因此这需要为同一文件中与搜索匹配的行着色。

这里的主要要求是我需要将这些颜色保存在我的原始文本文件中，而不仅仅是在终端上

例如

line
lactose
galactose
glusocse
lactose
lactos

我需要搜索乳糖以及给乳糖着色（例如黄色）

答案1

我已经为此编写了一个脚本：

#!/usr/bin/env perl
use Getopt::Std;
use strict;
use Term::ANSIColor; 

my %opts;
getopts('himc:l:',\%opts);
if ($opts{h}) {
    print<<EoF; 
DESCRIPTION

$0 will highlight the given pattern in color. 

USAGE

$0 [OPTIONS] -l PATTERN FILE

If FILE is omitted, it reads from STDIN.

-c : comma separated list of colors
-h : print this help and exit
-l : comma separated list of search patterns (can be regular expressions)
-m : only print matching lines (grep-like)
-s : makes the search case sensitive

EoF
    exit(0);
}

my $case_sensitive=$opts{s}||undef;
my $only_matching=$opts{m}||undef;
my @color=('bold red','bold blue', 'bold yellow', 'bold green', 
           'bold magenta', 'bold cyan', 'yellow on_magenta', 
           'bright_white on_red', 'bright_yellow on_red', 'white on_black');
## user provided color
if ($opts{c}) {
    @color=split(/,/,$opts{c});
}
## read patterns
my @patterns;
if ($opts{l}) {
    @patterns=split(/,/,$opts{l});
} else {
    die("Need a pattern to search for (-l)\n");
}

# Setting $| to non-zero forces a flush right away and after 
# every write or print on the currently selected output channel. 
$|=1;

while (<>) {
    my $matched;
    for (my $c=0; $c<=$#patterns; $c++) {
    if ($case_sensitive) {
        if (/$patterns[$c]/) {
        s/($patterns[$c])/color("$color[$c]").$1.color("reset")/ge && $matched++; 
        }
    } else {
        if (/$patterns[$c]/i) {
        s/($patterns[$c])/color("$color[$c]").$1.color("reset")/ige && $matched++; 
        }
    }
    }
    ## Skip non-matching lines
    if ($only_matching) {
        next unless $matched;
    }

    print STDOUT;
}

将文件另存为~/bin/color，使其可执行（chmod 755 ~/bin/color），然后运行它，为其提供要着色的图案的逗号分隔列表：

在此处输入图片描述

因此，要为输入文件的行着色，您只需使用上面的脚本，将输出重定向到新文件，然后重命名原始文件：

在此处输入图片描述

答案2

键入以下命令：

sudo nano /etc/bash.bashrc

一直击打PgDn直到到达终点。

复制粘贴以下文本：

alias grep-grey="GREP_COLOR='1;30' grep --color=always"
alias grep-red="GREP_COLOR='1;31' grep --color=always"
alias grep-green="GREP_COLOR='1;32' grep --color=always"
alias grep-yellow="GREP_COLOR='1;33' grep --color=always"
alias grep-blue="GREP_COLOR='1;34' grep --color=always"
alias grep-magenta="GREP_COLOR='1;35' grep --color=always"
alias grep-cyan="GREP_COLOR='1;36' grep --color=always"
alias grep-white="GREP_COLOR='1;37' grep --color=always"

按Ctrl+X然后Y按Enter

退出所有终端

进入新终端并输入：

grep-yellow lactose /path/to/file

并惊奇地凝视！;-)

相关内容