☰

并排比较两个以上包含数值的文件

tag-icon • tag-icon text-processing awk diff
并排比较两个以上包含数值的文件

我有三个文件，其中包含已排序的数字序列，每行一个：

文件1

1
2
3

文件2

1
3
4

文件3

1
5

我想并排“对齐”这三个文件，如下所示：

file1  file2  file3
1      1      1
2      
3      3
       4
              5

我试过了sdiff，但它只适用于 2 个文件

答案1

您可以处理每个文件并打印带有某些字符的行，例如X序列 1- 中每个缺失的数字最大限度（在哪里最大限度是该文件中的最后一个数字），paste然后结果将该字符替换为空格：

paste \
<(awk 'BEGIN{n=1};{while (n<$1) {print "X";n++}};{n=$1+1};1' file1) \
<(awk 'BEGIN{n=1};{while (n<$1) {print "X";n++}};{n=$1+1};1' file2) \
<(awk 'BEGIN{n=1};{while (n<$1) {print "X";n++}};{n=$1+1};1' file3) \
| tr X ' '

如果所有文件中缺少某个值，您将在输出中得到空行（实际上它们不是空的，它们只包含空格）。
要删除它们，请替换tr X ' ' 为sed '/[[:digit:]]/!d;s/X/ /g' Also，如果您需要标头，您始终可以先运行如下所示的内容：

 printf '\t%s' file1 file2 file3 | cut -c2-

答案2

awk 的通用解决方案：需要 GNU awk

gawk -v level=0 '
    FNR==1 {level++; head[level]=FILENAME}
    !seen[$1]++ { n++; idx[$1] = n }
    { out[idx[$1]][level] = $1 }
    END {
        for (j=1; j<=level; j++) {
            printf "%s\t", head[j]
        }
        print ""
        for (i=1; i<=n; i++) {
            for (j=1; j<=level; j++) {
                printf "%s\t", out[i][j]
            }
            print ""
        }
    }
' file{1,2,3,4}

file1   file2   file3   file4   
1   1   1       
2           2   
3   3           
    4       4   
        5       
            6

根据唐的评论，采取了一种不同且更简单的方法：

gawk '
    FNR==1 { printf "%s\t", FILENAME }
    { seen[$1][FILENAME] = $1 } 
    END {
        print ""
        PROCINFO["sorted_in"]="@ind_num_asc"
        for (i in seen) {
            for (j=1; j<=ARGC; j++) {
                printf "%s\t", seen[i][ARGV[j]]
            } 
            print ""
        }
    }
' file{1,2,3,4}

file1   file2   file3   file4       
    1   1           
            2       
3   3               
    4       4       
5       5           
            6       
7

答案3

bash带有、join、paste、 和坏味道的解决方案：

#! /usr/bin/env bash

if [ $# -lt 3 ]; then exit 1; fi

files=( '' "$@" )

declare -a temps
for ((i=0; i<=$#; i++)); do
    [ $i -eq 0 -o -f "${files[$i]}" ] || exit 1
    temps[$i]=$( mktemp -t "${0##*/}"_$$_XXXXXXXX ) || exit 1
done
trap 'rm -f "${temps[@]}"' EXIT HUP INT QUIT TERM

cat "$@" | sort -u >"${temps[0]}"

TAB=$( printf '\t' )
for ((i=1; i<=$#; i++)); do
    join -j1 -a1 -t"$TAB" "${temps[0]}" <(paste "${files[$i]}" "${files[$i]}") | \
        sed "/^[^$TAB]\$/ s/\$/$TAB/" >"${temps[$i]}"
done

printf '%s' ${files[1]}
for ((i=2; i<=$#; i++)); do
    printf '\t%s' ${files[$i]}
    let j=i-1
    let k=i-2
    join -j1 -t"$TAB" "${temps[$j]}" "${temps[$i]}" >"${temps[$k]}"
    cat "${temps[$k]}" >"${temps[$i]}"
done
printf '\n'

cut -d "$TAB" -f 2- <"${temps[$#]}" | sort -n

除了最后一个之外sort -n，所有这些都适用于任何文本项而不是数字，只要这些项不包含制表符（但TAB可以更改为任何其他分隔符）。另外，只需 3 个临时文件和一些乱七八糟的东西就可以完成（但这只会增加不好的品味）。

相关内容