☰

从 bash 转移到 zsh

tag-icon • tag-icon bash command-line zsh
从 bash 转移到 zsh

我正在考虑从 bash 转到 zsh，因为我经常看到赞扬 zsh 的帖子。我是一名经验丰富的命令行用户，我认为基本原理基本相同，所以我正在寻找建议，以了解迁移的好处以及需要注意的任何陷阱。

请在每个答案中只给出一点建议。我正在寻找小块内容，这样我就可以回来并以稳定的速度将额外的信息整合到我的 shell 使用中，而不是试图一次性学习所有内容。

答案1

正如您所说，zsh在很多方面与 相似bash。它具有 中没有的一些功能bash，并且可以以强大的方式进行扩展。不要将移动视为一种革命，而应将其视为一系列有助于您日常工作的进化步骤。以下是我的 的一些提示.zshrc。虽然您说您更喜欢单条建议，但这篇文章是一个较长的列表。不过，逐一浏览这些要点仍然是一个好主意。只需将有趣的部分添加到您的~/.zshrc并重新加载 即可。最后一条提示：了解的默认（“Emacs”）键盘快捷键source ~/.zshrc的按键： 。您可以用两个单独的按键替换：相当于。zsh^A ^E ^W Alt-F Alt-B Alt-P ^L ^RAltAlt-PESC P

这为您提供了更广泛的制表符补全。

autoload -U compinit
compinit

从两端完成制表符。

setopt completeinword

制表符补全应该不区分大小写。

zstyle ':completion:*' matcher-list 'm:{a-zA-Z}={A-Za-z}'

更好地完成 killall。

zstyle ':completion:*:killall:*' command 'ps -u $USER -o cmd'

改变“单词”的定义，例如使用^W。

autoload select-word-style
select-word-style shell

ls 的颜色。

if [[ -x "`whence -p dircolors`" ]]; then
  eval `dircolors`
  alias ls='ls -F --color=auto'
else
  alias ls='ls -F'
fi

ls 的快捷方式。

alias ll='ls -l'
alias la='ls -a'

所有打开的 shell 都有一个历史记录；存储 10,000 个条目。这使其成为一种有用的记忆辅助工具，可用于查找上次使用的命令./configure等。请自由使用 Alt-P（查找以此开头的命令）和 ^R（在历史记录中搜索）。

HISTFILE=~/.zhistory
HISTSIZE=SAVEHIST=10000
setopt sharehistory
setopt extendedhistory

启用各种扩展通配符，例如 ls **/*.txt（查找所有文本文件），ls -d *(D)（显示所有文件，包括以“。”开头的文件）。要了解更多信息，请转至man zshexpn“文件名生成”部分。

# superglobs
setopt extendedglob
unsetopt caseglob

这对于记住历史命令而不执行它们很有用。

setopt interactivecomments # pound sign in interactive prompt

输入“..”而不是“cd ..”，输入“/usr/include”而不是“cd /usr/include”。

setopt auto_cd

很好的提示。

PS1='[%T] %n@%m:%~# '

显示耗时超过 10 秒的命令的 CPU 使用率统计信息

REPORTTIME=10

一些在 Ubuntu 中广泛使用的命令。

alias 'a=sudo aptitude'
alias 'ai=sudo aptitude install'
alias 'ar=sudo aptitude remove'
alias 'au=sudo aptitude update'
alias 'ag=sudo aptitude safe-upgrade'
alias 'as=apt-cache search'
alias 'aw=apt-cache show'

按大小排序列出包 - 在确定哪些包占用了您的磁盘空间时很有用。

function apt-list-packages {
  dpkg-query -W --showformat='${Installed-Size} ${Package} ${Status}\n' | grep -v deinstall | sort -n | awk '{print $1" "$2}'
}

答案2

我会推荐这本书从 bash 到 Z Shell。它提供了切换 shell 所需的所有建议。它解释了两种 shell 的区别，让 zsher 新手也能轻松上手。

答案3

这是我的.zshrc这是最重要的事情！zsh 有很多你可以使用的选项，所以看看网络上的一些例子，或者阅读Zsh 主页。

除了命令行右侧的时间戳之外，我的 .zshrc 不包含任何真正酷的东西。

顺便说一句，记得在各处尝试制表符补全，这里有几个例子：

mplayer -a[tab]

将显示如下内容：

mplayer -a
 -ac                 -- force usage of a specific audio codec
 -af                 -- activate audio filters
 -afm                -- force usage of a specific audio codec family
 -alang              -- select the DVD audio language
 -ao                 -- specify audio driver
 -aop                -- specify audio output filter

如果你使用无密码 ssh-keys 或 ssh-agent，你可能会发现它对于制表符补全远程文件很有用：

scp apollo:/home/user/[tab]
Desktop/ Documents/ Downloads/ Music/ Pictures/ Public/ Templates/ Videos/

获取列表后，您可以多次按下 Tab 键来循环浏览不同的可能性。

但是要注意，这个 shell 会让你变得懒惰，并且让你觉得标准 shell 很愚蠢、很烦人！

答案4

我对 bash 了解不多，所以无法比较。以下是我的 zsh 配置文件中的一些片段。

一些配置

HISTFILE=~/.zsh_history
HISTSIZE=1000
SAVEHIST=1000
REPORTTIME=10 # print elapsed time when more than 10 seconds
setopt NO_HUP
setopt NO_LIST_BEEP
setopt LOCAL_OPTIONS # allow functions to have local options
setopt LOCAL_TRAPS # allow functions to have local traps
setopt HIST_VERIFY
setopt SHARE_HISTORY # share history between sessions ???
setopt EXTENDED_HISTORY # add timestamps to history
setopt PROMPT_SUBST
setopt CORRECT
setopt COMPLETE_IN_WORD
setopt IGNORE_EOF

setopt APPEND_HISTORY # adds history
setopt INC_APPEND_HISTORY SHARE_HISTORY  # adds history incrementally and share it across sessions
setopt HIST_IGNORE_ALL_DUPS  # don't record dupes in history
setopt HIST_REDUCE_BLANKS
# Leave some chars out of the out of WORDCHARS so ^W acts more nicely 
WORDCHARS='*?_-[]~\!#$%^(){}<>|`@#$%^*()+:?'

Git 在提示符中

if [[ -n $SSH_CONNECTION ]]; then
  export PS1='%m:%3~$(git_info_for_prompt)%# '
else
  export PS1='%3~$(git_info_for_prompt)%# '
fi

一些热键，在行首插入一些文本。

insert_sudo     () { zle beginning-of-line; zle -U "sudo "         }
insert_apt      () { zle beginning-of-line; zle -U "sudo apt-get " }
insert_gem      () { zle beginning-of-line; zle -U "sudo gem "     }
insert_install  () { zle -U "install "     }

zle -N insert-sudo      insert_sudo
zle -N insert-apt       insert_apt
zle -N insert-gem       insert_gem
zle -N insert-install   insert_install

bindkey "^B" insert-gem
bindkey "^N" insert-install
bindkey "^k" insert-sudo
bindkey "^a" insert-apt

这些函数我存储在 ~/.zsh/functions 中

git_info_for_prompt

local g="$(git rev-parse --git-dir 2>/dev/null)"
if [ -n "$g" ]; then
  local r
  local b
  if [ -d "$g/../.dotest" ]
  then
    if test -f "$g/../.dotest/rebasing"
    then
      r="|REBASE"
    elif test -f "$g/../.dotest/applying"
    then
      r="|AM"
    else
      r="|AM/REBASE"
    fi
    b="$(git symbolic-ref HEAD 2>/dev/null)"
  elif [ -f "$g/.dotest-merge/interactive" ]
  then
    r="|REBASE-i"
    b="$(cat "$g/.dotest-merge/head-name")"
  elif [ -d "$g/.dotest-merge" ]
  then
    r="|REBASE-m"
    b="$(cat "$g/.dotest-merge/head-name")"
  elif [ -f "$g/MERGE_HEAD" ]
  then
    r="|MERGING"
    b="$(git symbolic-ref HEAD 2>/dev/null)"
  else
    if [ -f "$g/BISECT_LOG" ]
    then
      r="|BISECTING"
    fi
    if ! b="$(git symbolic-ref HEAD 2>/dev/null)"
    then
      if ! b="tag: $(git describe --exact-match HEAD 2>/dev/null)"
      then
        b="$(cut -c1-7 "$g/HEAD")..."
      fi
    fi
  fi

  if [ -n "$1" ]; then
    printf "$1" "${b##refs/heads/}$r"
  else
    printf "[%s]" "${b##refs/heads/}$r"
  fi
fi

一些 Github 选项

#compdef github

_github() {
  if (( CURRENT > 2 )); then
    # shift words so _arguments doesn't have to be concerned with second command
    (( CURRENT-- ))
    shift words
    # use _call_function here in case it doesn't exist
    _call_function 1 _github_${words[1]}
  else
    _values "github command" \
     "fetch[Fetch from a remote to a local branch.]" \
     "ignore[Ignore a SHA (from 'github network commits')]" \
     "fetch_all[Fetch all refs from a user]" \
     "info[Info about this project.]" \
     "browse[Open this repo in a web browser.]" \
     "home[Open this repo's master branch in a web browser.]" \
     "clone[Clone a repo.]" \
     "pull-request[Generate the text for a pull request.]" \
     "network[Project network tools.]" \
     "pull[Pull from a remote.]" \
     "track[Track another user's repository.]"
  fi
}

_github_pull() {
  _arguments \
    "--merge[Automatically merge remote's changes into your master.]"
}
_github_clone() {
  _arguments \
    "--ssh[Clone using the [email protected] style url.]"
}

_github_track() {
  _arguments \
    "--private[Use [email protected]: instead of git://github.com/.]" \
    "--ssh[Equivalent to --private.]"
}

_github_network() {
  if (( CURRENT > 2 )); then
    # shift words so _arguments doesn't have to be concerned with second command
    (( CURRENT-- ))
    shift words
    # use _call_function here in case it doesn't exist
    _call_function 1 _github_network_${words[1]}
  else
    _values "github network command" \
     "web[Open network in a web browser.]" \
     "list[List networked repositories.]" \
     "fetch[Fetched commits for a given networked repository.]" \
     "commits[List networked commits not pulled into this repo.]"
  fi
}

_github_network_commits() {
  _arguments \
    "--project[Filter commits on a certain project.]" \
    "--author[Filter commits on a email address of author.]" \
    "--common[Show common branch point.]" \
    "--nocache[Do not use the cached network data.]" \
    "--sort[How to sort : date(*), branch, author.]" \
    "--thisbranch[Look at branches that match the current one]" \
    "--applies[Filter commits to patches that apply cleanly.]" \
    "--limit[Only look through the first X heads - useful for really large projects]" \
    "--before[Only show commits before a certain date.]" \
    "--after[Only show commits after a certain date.]" \
    "--shas[Only show shas.]" \
    "--cache[Use the network data even if it's expired.]" \
    "--noapply[Filter commits to patches that do not apply cleanly.]"
}

相关内容