☰

在 Excel 中切换工作表的键盘快捷键

tag-icon • tag-icon microsoft-excel keyboard-shortcuts microsoft-excel-2007
在 Excel 中切换工作表的键盘快捷键

Excel 2007 是否有在工作表之间切换的键盘快捷键？

答案1

Ctrl+PgUp向左移动。

Ctrl+PgDn向右移动。

答案2

VBA 宏和自定义键盘快捷键激活第一张或最后一张工作表

如果您想要实际的键盘快捷键跳转到第一个或最后一个工作表，请将此代码放入“PERSONAL”工作簿中的模块中：

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

转到“开发人员”选项卡 > 宏。浏览到这些宏（ToFirstSheet 和 ToLastSheet）。选择一个，单击“选项”并分配键盘快捷键。对另一个执行相同操作。

通过将其保存到“个人”工作簿，它将可用于任何 Excel 文件。

内置键盘快捷键可激活上一张或下一张工作表

要向左或向右跳转一个工作表，您可以使用以下默认的键盘快捷键：

Ctrl+PgUp

Ctrl+PgDn

用于激活上一张或下一张工作表的 VBA 宏

以下是使用 VBA 完成相同操作的方法，请尝试以下操作：

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

VBA 函数返回上一个或下一个工作表

如果您希望获取上一个或下一个工作表对象，请使用此功能：

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

使用如下函数：

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

答案3

您还可以使用加速键进入Go对话框。然后您可以输入一些内容，例如foo!A1导航到名为“foo”的工作表中左上角的单元格。虽然向上翻页和向下翻页通常更快。如果您有大量（例如 20 个以上）命名良好的工作表，这可能会更快。如果您的工作表中有命名的表格，Go 也能很好地工作。

按 F5 通常会打开Go对话框。

相关内容