☰

Windows XP 及更高版本

tag-icon • tag-icon windows-7 windows-xp batch-file date
Windows XP 及更高版本

在批处理文件中，我需要从 date 命令中提取月份、日期、年份。因此，我使用了以下命令，它本质上解析了 Date 命令以将其子字符串提取到变量中：

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

这一切都很棒，但是如果我将此批处理文件部署到具有不同区域/国家设置的机器上，它就会失败，因为月份、日期和年份位于不同的位置。

无论日期格式如何，如何提取月份、日期和年份？

答案1

来源： http://ss64.com/nt/syntax-getdate.html

方法 2（单个 cmd）

获取日期

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

在此处输入图片描述

方法 1（cmd+vb）

获取日期

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

获取日期工具

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

答案2

Windows XP 及更高版本

获取日期

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

输出

在此处输入图片描述

答案3

我知道这不完全是您所要求的，但是我使用date批处理文件内的命令中的 Linux 应用程序的 Windows 端口，然后将结果分配给变量。

我还没有找到仅使用批处理命令可靠地获取日期的方法。

答案4

虽然您说得对，VS 2008 输出批处理文件，但您几乎可以运行任何您想要的程序，包括 Powershell 脚本和其他程序。

编辑：

以下是一些类似的问题：

https://stackoverflow.com/questions/1051845/visual-studio-2008-professional-build-process https://stackoverflow.com/questions/3049369/embed-application-compilation-time-stamp

最初，我打算将其移至 SO……

相关内容