☰

使用键盘移动窗口...更快？

tag-icon • tag-icon windows keyboard-shortcuts gui
使用键盘移动窗口...更快？

我喜欢使用键盘快捷键，因为它更快，因为它不会强迫我将手从键盘上移开。

在 Windows 中，我可以使用它们在桌面上移动窗口：

  1. 按Alt+Space打开常用窗口菜单
  2. 按下M选择“移动”命令
  3. 通过光标键导航窗口位置
  4. 确认新位置Enter

此外，为了获得更好的准确性，我可以Ctrl在导航时按住。

现在的问题是，移动时的正常“步进”约为 20px，而我的桌面很大，因此“走”完一整段需要很长时间。这有点违背了使用键盘执行这些任务的目的。

是否可以改变这一步的大小，以便用更少的步数走完相同的距离？（我想象 Windows 注册表中有一个隐藏的设置……？）

我尝试过Alt在导航时按住，但它似乎对速度没有影响。

答案1

如果你想彻底改造窗口范式，实现动态平铺，可以考虑使用 AutoHotkey 脚本“错误“如果您喜欢通过键盘操作窗口，您会喜欢它。

答案2

像你这样通过键盘移动是精确的，但却很乏味。

如果你通常将窗口移动到特定位置和大小，那么尝试网格移动。您可以定义自己的网格（窗口位置和大小），也可以使用预定义的网格。每个网格都称为图块。之后，您可以按 Win+2 捕捉任何活动窗口，其中 2 是您希望它捕捉到的图块编号。按 Win+G 可查看当前网格中的图块及其编号。

答案3

在 Windows 7 上，您可以使用 Windows 键 + 箭头键来移动窗口。

我不确定它每次会移动多少个像素，但肯定超过 20 个。

答案4

虽然不太符合主题，但我觉得它仍然相关且值得分享。

我用自动热键和一个“KDEStyle”脚本我很早以前就发现了这一点，并且已经进行了调整以改进鼠标的使用。

  • Win+Left Click
    • 允许您通过单击移动窗口任何地方在里面。
  • Win+Right Click
    • 允许您使用最近的角调整窗口大小 - 再次单击任何地方在里面。

这大大降低了所需的精度，并且在我看来，使用鼠标实现此类目的变得更加容易和快捷。

#LButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,,,ahk_id %KDE_id%
    loop {
        GetKeyState,KDE_Button,LButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        KDE_WinX2 := (KDE_WinX1 + KDE_X2)
        KDE_WinY2 := (KDE_WinY1 + KDE_Y2)
        WinMove,ahk_id %KDE_id%,,%KDE_WinX2%,%KDE_WinY2%
    }
    return

#RButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
    if (KDE_X1 < KDE_WinX1 + KDE_WinW / 2) {
        KDE_WinLeft := 1
    } else {
        KDE_WinLeft := -1
    }
    if (KDE_Y1 < KDE_WinY1 + KDE_WinH / 2) {
        KDE_WinUp := 1
    } else {
        KDE_WinUp := -1
    }
    loop {
        GetKeyState,KDE_Button,RButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        WinMove,ahk_id %KDE_id%,, KDE_WinX1 + (KDE_WinLeft+1)/2*KDE_X2
                                , KDE_WinY1 +   (KDE_WinUp+1)/2*KDE_Y2
                                , KDE_WinW  -     KDE_WinLeft  *KDE_X2
                                , KDE_WinH  -       KDE_WinUp  *KDE_Y2
        KDE_X1 := (KDE_X2 + KDE_X1)
        KDE_Y1 := (KDE_Y2 + KDE_Y1)
    }
    return

标准 Windows 键盘组合对此进行了补充，并允许您：

  • Win+ Up/Down
    • 最大化/恢复/最小化
  • Win+ Left/Right
    • 调整至屏幕左/右半部分
  • Win+ Shift+ Left/Right
    • 向左/向右移动一个监视器
  • ETC...

相关内容