Windows 7 功能或免费软件可让某个窗口始终位于其他窗口下方

Question 1

很久以前，Windows 有一个名为 X-Mouse 的 PowerToy（后来更名为 TweakUI），它除其他功能外，还支持旧式 X“焦点跟随鼠标”，其中“焦点”和“前景”不是一回事。我认为它不再维护了（最后一次看到它是针对 WinXP 的）。

虽然我没有广泛使用过，但免费的 Windows 脚本工具汽车信息技术可以用一个简短的脚本做你想做的事情：

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>
#include <SendMessage.au3>

Local $hWnd,$flags,$regexp

Func MyExit() 
    MsgBox(0,"Drop Window","Quitting!",2) 
    Exit 0
EndFunc

$flags = BitOr($SWP_NOMOVE,$SWP_NOSIZE,$SWP_NOACTIVATE,$SWP_ASYNCWINDOWPOS,$SWP_NOSENDCHANGING) 

;; hot key to call exit: ALT + F11
HotKeySet("!{F11}","MyExit")

;; application window title
$regexp=".*Notepad$"

;; 10 second time out on first startup, 
$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]", "", 10)
;; or wait forever
;$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]")

If ($hWnd) Then
    ;; uncomment next line to maximize window first
    ;_SendMessage($hWnd,$WM_SYSCOMMAND,$SC_MAXIMIZE)

    _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);

    While 1
        If WinWaitActive($hWnd,"",10) Then
            _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);
        EndIf
        ;; check for new window
        $hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]","",1) 

        ;; uncomment next 3 lines to quit if no window
        ;if (NOT $hWnd) Then
        ;    MyExit()
        ;EndIf

        Sleep(250)
    Wend
Else
    MsgBox(0,"Drop Window","No window title matching /" & $regexp & "/") 
EndIf

“topmost” 是 WM 维护的持久窗口属性，没有等效的“bottom most”，因此我们必须对其进行一些修改。

While 循环等待应用程序进入前台，然后再次将其置于前台，同时保持键盘焦点。模式弹出窗口有时会干扰此操作，但它应该非常有用。监视程序终止后，脚本将继续在后台运行。Alt+F11 可随时退出。

更改 $regexp 以匹配“mIRC”或其他内容。以上方法每次只能可靠地处理一个窗口。阅读 AutoIT 文档中的 WinWait() 以了解如何匹配除窗口标题以外的窗口。

保存到dropwindow.au3并使用“autoit3 dropwindow.au3”运行它。

http://www.autoitscript.com/site/autoit/downloads/

Answer

很久以前，Windows 有一个名为 X-Mouse 的 PowerToy（后来更名为 TweakUI），它除其他功能外，还支持旧式 X“焦点跟随鼠标”，其中“焦点”和“前景”不是一回事。我认为它不再维护了（最后一次看到它是针对 WinXP 的）。