☰

PowerPoint - 为每张幻灯片设置时间并显示总演示时间？

tag-icon • tag-icon microsoft-powerpoint microsoft-powerpoint-2013
PowerPoint - 为每张幻灯片设置时间并显示总演示时间？

我知道您可以在过渡选项卡中为每张幻灯片设置一个时间，但这是在您使用它来自动过渡每张幻灯片时。

我希望每张幻灯片上都有一个可以设置的时间属性。然后，作为演示者，它会显示倒计时，这样我在演示时就可以知道任何特定幻灯片上的时间是否超出/不足。

此外，如果能够确定演示文稿的总时间，那就太好了。因此，在底部工具栏上，将有一个项目表示幻灯片时间 = 01:30，另一个项目表示幻灯片放映时间 = 05:45

我担心这个功能无法实现，但我认为如果有的话会非常非常有用。

这里的关键点是我仍然想控制演示，所以我不想使用自动幻灯片切换。但我希望能够使用幻灯片切换时间之类的值（以及所有这些值的总和），以便更好地准备和展示我的节目。

编辑：我发现我可以在幻灯片放映->设置区域中关闭“使用计时”，这样就可以停止每张幻灯片后的自动前进，同时仍在幻灯片放映页面上显示每张幻灯片的时间。但这并不能在演示过程中为我提供幻灯片计时器，也不能让我看到演示的总时间（如果你有 30-45 张幻灯片，那么将每张幻灯片的时间加起来会很烦人）。

答案1

您可以下载一个插件，它能满足您的需求。既然您已经设置了第一部分，您可以使用它加入在当前幻灯片顶部显示已用时间。

我链接到的网站上有安装说明，但为了方便起见，我将把它们包括在这里。

  1. 下载可执行文件并让其将插件安装到默认位置。我已扫描可执行文件和已安装的插件文件以查找病毒，并确认它们没有病毒。

  2. 安装插件后，打开 PowerPoint 并执行以下操作：

文件 -> 选项 -> 加载项 ->（从底部的管理下拉菜单中）选择 PowerPoint 加载项并转到

  1. 在出现的对话框中执行以下操作：

添加新 -> 选择 TM PowerPoint 计时器（功能区 UI） -> 确定

以上操作将TM在 PowerPoint 功能区中添加一个选项卡。在计时器的配置窗口中，您可以设置一个计时器来显示已用时间。Update Display第一个选项卡上还有一个条目，因此请确保将其设置为 1 秒（默认值为 10 秒）。

答案2

回答我自己的问题：我发现了这个，它可以提供幻灯片放映的总时间。它基于幻灯片自动过渡设置的时间（过渡->前进幻灯片->之后：）。在幻灯片放映功能区中，您可以禁用“使用计时”，这样您就可以控制演示时幻灯片的前进。

这不会在演示者的视图上提供幻灯片倒计时，但我想我可以不用它，只需在笔记顶部输入我应该到达的预计时间即可。上面的插件似乎会在演示者的视图上提供倒计时，但我无法在我的场地使用它，所以这不是一个选项。

我根据这里制作了这个宏，PowerPoint 常见问题解答。 我对其进行了少许修改，以便以“00:00”格式显示时间，并在底部显示总时间，而不是单独弹出。要使用它，只需创建一个，转到“查看”->“宏”，然后创建一个新的宏“总时间”。复制并粘贴以下代码：

Sub TotalTimes()

Dim oSld As Slide
Dim strMessage As String
Dim lngTotalTime As Long
Dim strSlideMin As String
Dim strSlidesec As String


' Use this to collect times for ALL slides:
For Each oSld In ActivePresentation.Slides
' Or comment it out and uncomment this to get just the selected slides:
' For Each oSld in ActiveWindow.Selection.SlideRange
    strSlideMin = Format(Int(oSld.SlideShowTransition.AdvanceTime / 60), "00")
    strSlidesec = Format(Int(oSld.SlideShowTransition.AdvanceTime Mod 60), "00")
    strMessage = strMessage _
        & CStr(oSld.SlideNumber) _
        & vbTab _
        & strSlideMin & ":" & strSlidesec _
        & vbCrLf
    lngTotalTime = lngTotalTime + oSld.SlideShowTransition.AdvanceTime
Next oSld

' Comment these out if you don't want to see them
strMessage = strMessage & vbCrLf & "Total" & vbTab & Format(Int(lngTotalTime / 60), "00") & ":" & Format(Int(lngTotalTime Mod 60), "00")
MsgBox strMessage
'MsgBox ("Total time: " & CStr(lngTotalTime))


End Sub

原始代码还包括一个写入文本文件的部分，但由于它不符合我的需要，所以我将其删掉了。

我非常非常惊讶微软在 PowerPoint 中没有提供这些信息。这似乎是他们默认包含的相当直观的信息。

答案3

通过插件有更优雅的方法来实现这一点，但是这样怎么样...它假设您正在使用演示者视图，您可以在其中看到注释，但您可以将文本添加到幻灯片或其他任何内容。

Option Explicit
Public StartTime As Date

Sub StartTimer()
    StartTime = Time
    SlideShowWindows(1).View.GotoSlide (SlideShowWindows(1).View.Slide.SlideIndex + 1)
End Sub

Sub ElapsedTime(osh As Shape)

    Dim oNotesText As Shape
    Dim oNextSlide As Slide

    ' what slide are we about to move TO?
    Set oNextSlide = ActivePresentation.Slides(osh.Parent.SlideIndex + 1)

    ' Get a reference to the notes text on that slide (not 100% reliable, but generally works)
    Set oNotesText = oNextSlide.NotesPage.Shapes(2)

    ' Do the time math and add the elapsed time to the notes:
    With oNotesText
        .TextFrame.TextRange.Text = Format(Time - StartTime, "HH:MM:SS") & vbCrLf & .TextFrame.TextRange.Text
    End With

    ' And go to the slide
    SlideShowWindows(1).View.GotoSlide (SlideShowWindows(1).View.Slide.SlideIndex + 1)

End Sub

在第一张幻灯片中添加一个形状，并为其分配“运行宏的操作设置”：StartTimer 在第二张幻灯片中添加一个形状，并为其分配“运行宏的操作设置”：ElapsedTime 将第二张幻灯片中的形状复制并粘贴到演示文稿中的其他幻灯片中。

答案4

我想对从上面的 PowerPoint FAQ 中提取的宏添加一条评论。它非常有用，但还不够。我使用原始版本试图找出幻灯片与某些音乐曲目无法正确同步的原因。

在消除（大部分）小学生错误后，缺失的内容就一目了然了。每张幻灯片都有 1 秒的过渡时间。对于幻灯片较少的曲目，额外的时间“丢失”了，但对于较长的曲目，这些额外的时间变得显而易见。

还有一个问题。在一些幻灯片上，动画的总持续时间比幻灯片前进时间长，这增加了延迟（这是被忽视的小学生错误）。因此，宏中至少需要一行额外的代码：

strMessage = strMessage _
    & CStr(oSld.SlideNumber) _
    & vbTab _
    **& CStr(oSld.SlideShowTransition.Duration) _
    & vbTab _**
    & CStr(oSld.SlideShowTransition.AdvanceTime) _
    & vbCrLf

在表格中添加一个额外的列来显示过渡的持续时间，并修改显示以将持续时间包含在总时间中：lngTotalTime = lngTotalTime + oSld.SlideShowTransition.AdvanceTime+ oSld.SlideShowTransition.持续时间 不过，您或许更愿意分别查看这两个元素的总数。

我没有解决幻灯片上动画持续时间大于总前进时间的问题，但我确实想到在消息中包含每个动画的总时间（包括它们在报告中的延迟时间）会很有用，因为任何超过前进时间的时间都会增加幻灯片放映的长度，但也可能是无意的。

相关内容