☰

如何计算公式中的行？链接到特定单元格

tag-icon • tag-icon microsoft-excel microsoft-excel-2013
如何计算公式中的行？链接到特定单元格

例如：链接到单元格 A1 是“ =A1”
A - 列名
1 - 行号

我可以计算公式中的行号来创建特定链接吗？
类似=A{some calculations}这样的=A{1+1}链接将是单元格 A2 的链接

答案1

是的，但是它是这样完成的
=OFFSET(Start_Cell, Rows_Up_or_Down, Columns_Right_or_Left [, Number_of_Rows [, Number_of_Columns]])
，假设您的信息从 C5 开始，并且您想要 1 个向下 4 行、向右 2 列的单元格：
=OFFSET(C5,4,2)

答案2

在 Excel 中有几种方法可以做到这一点。LDC3 的答案描述了 OFFSET。另一种是：

    =INDIRECT(reference,style)

这将从文本输入创建对单元格的引用。这为计算或创建单元格引用提供了很大的自由度。

    =INDIRECT("A"&(1+1))   is equivalent to =A2
    =INDIRECT("A"&ROW())   if this formula is in cell C5, 
                           this would be equivalent to =A5

如果样式参数为“TRUE”或省略，则采用正常单元格引用格式，如上所述。

INDIRECT 还允许使用不同的行和列指定样式。如果样式参数为“FALSE”，则使用R#C#字母R表示下一个数字是行号，使用字母C表示下一个数字是列号（所有内容都指定为数字）。如果在 或 后省略数字R，C则假定您指的是当前行或列。

    =INDIRECT("R1C1",FALSE)    is equivalent to =A1
    =INDIRECT("R"&(ROW()-4)&"C",FALSE) if this formula is in cell C5, 
                                       this would be equivalent to =C1 
                                       (current column, and row number equal to 
                                        the current row -4).

此格式允许您以数字形式计算行和列引用。它的功能与 OFFSET 类似，但相对于当前位置而不是锚点单元格。如果您将数字放在方括号中，则表示相对位置（距离当前单元格的行数或列数）。

    =INDIRECT("R3C[-2]",FALSE)  if this formula is in cell C5, 
                                this would be equivalent to =A3

答案3

=INDEX(A1:A100,1,2)       [this will give you row 1, column B]

或者

=INDEX(A1:Z100,1+1,2+2)   [this will give you row 2, column D]

= INDEX (TARGET:AREA, ROW, COLUMN)

如果您像我一样使用大量索引，索引将不会拖慢您的文档。间接和偏移会消耗更多资源。启动数千个间接或偏移，您的文档将开始拖慢所有正在处理的波动。

显然，你可以用不同的方式来打包，例如：

=INDEX(A1:Z100,ROW(A1)+1,COLUMN(B1)+2)

相关内容