☰

如何在不应自动更新的 Excel 表范围内插入时间？

tag-icon • tag-icon microsoft-excel microsoft-excel-2010 worksheet-function microsoft-excel-2007
如何在不应自动更新的 Excel 表范围内插入时间？

朋友们，我想在一个不应自动更新的范围内插入时间。例如，如果单元格 k5 中有任何值，则当前时间应自动插入单元格 N5 中。同样，如果 k6 中有任何值，则当前时间应自动插入 N6 中，依此类推。此外，它不应自动更新。我尝试使用这个公式

=如果 (K5 < 0，" "，如果 (K5 = 0，" "，NOW ()))

此公式有效，但它会自动使用系统时钟更新时间。我希望它不要更新时间。您也可以查看快照 - https://i.stack.imgur.com/v5Lqr.png 请帮助我...非常感谢...

答案1

首先输入您的列钾数据，然后运行这个简短的宏：

Sub RecordTime()
   Dim rng As Range, r As Range, d As Date
   Set rng = Intersect(Range(Cells(5, "K"), Cells(Rows.Count, "K")), ActiveSheet.UsedRange)
   d = TimeSerial(Hour(Now()), Minute(Now()), Second(Now()))

   For Each r In rng
      If r.Value <> "" Then
         r.Offset(0, 3) = d
      End If
   Next r
End Sub

编辑＃1：

这是代码的自动版本。插入以下内容事件宏在工作表代码区域：

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim rng As Range, r As Range, d As Date
   Set rng = Intersect(Range(Cells(5, "K"), Cells(Rows.Count, "K")), ActiveSheet.UsedRange)

   If Intersect(Target, rng) Is Nothing Then Exit Sub
   If Target.Count > 1 Then Exit Sub
   If Target.Offset(0, 1).Value <> "" Then Exit Sub

   d = TimeSerial(Hour(Now()), Minute(Now()), Second(Now()))
   Application.EnableEvents = False
      Target.Offset(0, 1).Value = d
   Application.EnableEvents = True

End Sub

如果您更改列中的单元格钾时间将自动记录在栏中大号。

因为它是工作表代码，所以非常容易安装和自动使用：

  1. 右键单击 Excel 窗口底部附近的选项卡名称
  2. 选择查看代码-这将打开一个 VBE 窗口
  3. 粘贴内容并关闭 VBE 窗口

如果您有任何疑虑，请首先在试用工作表上尝试一下。

如果您保存工作簿，宏将随之保存。如果您使用的是 2003 以后的 Excel 版本，则必须将文件保存为 .xlsm 而不是 .xlsx

要删除宏：

  1. 调出如上所示的 VBE 窗口
  2. 清除代码
  3. 关闭 VBE 窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其工作！

相关内容