☰

Excel 在工作表更改时自动在单元格中显示当前时间

tag-icon • tag-icon microsoft-excel microsoft-excel-2007
Excel 在工作表更改时自动在单元格中显示当前时间

在我的 A1、A2、…、A10 单元格中我有此代码

=IF(B1>0,NOW(),0)

因此，如果 B1>0，A1 等于现在的日期时间，并且所有这些都适用于 B2 和 A2 B3 和 A3 等等。

但问题是，如果我更改例如 B4，所有单元格从 A1 到 An 都会自动更改为 A4 的日期，实际上，如果我在这张表 A1 上执行某些操作...An 会自动更改为当前时间

答案1

试试这个简短的事件宏：

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim B As Range, I As Range, cell As Range
   Set B = Range("B1:B10")
   Set I = Intersect(Target, B)
   If I Is Nothing Then Exit Sub

   Application.EnableEvents = False
      For Each cell In I
         If cell.Value > 0 Then
            cell.Offset(0, -1).Value = Now()
         Else
            cell.Offset(0, -1).Value = 0
         End If
      Next cell
   Application.EnableEvents = True
End Sub

因为它是工作表代码，所以非常容易安装和自动使用：

  1. 右键单击 Excel 窗口底部附近的选项卡名称
  2. 选择查看代码-这将打开一个 VBE 窗口
  3. 粘贴内容并关闭 VBE 窗口

如果您有任何疑虑，请首先在试用工作表上尝试一下。

如果您保存工作簿，宏将随之保存。如果您使用的是 2003 以后的 Excel 版本，则必须将文件保存为 .xlsm 而不是 .xlsx

要删除宏：

  1. 调出如上所示的 VBE 窗口
  2. 清除代码
  3. 关闭 VBE 窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其工作！

相关内容