☰

具有多个 OR 条件范围的 Countif

tag-icon • tag-icon microsoft-excel worksheet-function
具有多个 OR 条件范围的 Countif

我使用的公式是：

=SUMPRODUCT(
COUNTIFS(
'Data'!$I:$I,UK!$I$3,
'Data'!$O:$O,MONTH(UK!K$5),
'Data'!$P:$P,YEAR(UK!K$5),
'Data'!$D:$D,$A13,
'Data'!$E:$E,**$C13:$F13**
)
)

我的问题是，如果我尝试添加另一个范围标准，例如，

'Data'!$A:A,**$C14:$F14**

公式最终得出的结果为 0，而不是数字。这不是正确的结果。有没有办法在单个 countifs 公式中包含多个“OR”范围？

答案1

要做多个OR语句，必须有一个垂直的，另一个水平的。

因此在第二个上使用转置：

=SUMPRODUCT(
COUNTIFS(
'Data'!$I:$I,UK!$I$3,
'Data'!$O:$O,MONTH(UK!K$5),
'Data'!$P:$P,YEAR(UK!K$5),
'Data'!$D:$D,$A13,
'Data'!$E:$E,$C13:$F13,
'Data'!$A:$A,Transpose($C13:$F13)
)
)

限制是标准中有两个这样的数组，一个水平，一个垂直。如果不拆分公式并对其进行求和，则无法完成 3 个或更多。

还可以尝试使用 SUM() 而不是 SUMPRODUCT。理论上，它应该可以与 SUM 一起用作常规公式。

答案2

听起来您想对多个 countif 求和。如果是这样，有多种方法可以做到这一点。一种易于调整或更改的方法如下。

  1. 范围是否独立？例如，I 列中的项目不会影响任何其他列，因此只需为该范围命名。

示例公式 [1] =countifs(Data'!$I:$I,UK!$I$3) 将其命名为 UK_I（使用公式功能区上的名称管理器。创建一个新名称）继续使用相同的格式，为每个独立的数据范围创建一个名称。

  1. 是否需要两个或多个条件为真才能计算？需要月份和年份都正确。制作一个包含 2 个范围的 countif。

示例公式 [2] = Countifs('Data'!$O:$O,MONTH(UK!K$5), 'Data'!$P:$P,YEAR(UK!K$5)) 将此命名为 UK_K

  1. 一旦拥有所有元素，sum(UK_I,UK_K,etc.....) 就可以将它们加起来。

一旦它开始工作，通过修改适当的名称或添加新名称来添加附加数据，就可以轻松调整。

相关内容