☰

bat 文件在 PC 中使用代理勾选或取消勾选

tag-icon • tag-icon windows proxy internet-explorer batch-file
bat 文件在 PC 中使用代理勾选或取消勾选

现在是一天中的那个时间，离开办公室坐在家里，打开你的笔记本电脑，你需要从控制面板> Internet 选项> 连接> 关闭代理来禁用 PC 级别的代理...第二天早上，在办公室做同样的事情，再次执行所有这些操作以再次启用它...接下来从运行中找到 inetcpl.cpl，以确保更容易地勾选/取消勾选并说确定

这很烦人，我想用 bat 文件或注册表键来实现这个功能，而不是一直这样做！经过多次搜索和尝试多种方案后，没有任何效果。

我知道浏览器有代理启用/禁用插件，并且在 Chrome 等上运行良好，但是为了使一切正常工作，需要从 Internet 选项中进行操作，以便在 PC 级别上进行...

欢迎任何可行的想法

谢谢

答案1

无需言语 :-)

:: EnableProxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f


:: Disable Proxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f


:: ToggleProxy.cmd
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
for /f "tokens=3" %%R in (
  'Reg Query "%Key%" /v %Val% ^|find /i "%Val%"'
) do if "%%~R" equ "0x0" (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f
) else (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f
)

我在 StackOverflow 上写过类似的在两个不同的代理之间切换。

相关内容