Excel 重复项公式

Question

有人可以向我展示一下创建 C 列中的精确数据所需的公式吗：

B 列中任何重复的单元格都会将 SKU 从 A 列复制到 C 列。

希望我已经解释清楚了这一点！！

Answer 1

如果您没有 Office 365 Excel，则需要 UDF。将此代码放入附加到工作簿的模块中：

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then 
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
    Else
        TEXTJOIN = ""
    End IF
End Function

然后以下数组公式将会执行您想要的操作：

=TEXTJOIN(" | ",TRUE,IF($A$2:$A$11<>A2,IF($B$2:$B$11=B2,$A$2:$A$11,""),""))

由于是数组公式，因此退出编辑模式时需要使用 Ctrl-Shift-Enter 而不是 Enter 进行确认。如果操作正确，Excel 会将{}公式放在一边。

---

如果您有 Office 365 Excel，只需使用上述公式作为数组公式，无需 UDF。

UDF 模仿了 TEXTJOIN 的功能。