☰

删除 Windows 10 Professional x64 系统托盘中的“主可执行模块”图标

tag-icon • tag-icon windows-10 icons notification-area
删除 Windows 10 Professional x64 系统托盘中的“主可执行模块”图标

我的系统托盘中出现了这两个图标。我有 Win10 Pro x64。它们为什么在那里？除了不显示它们之外，我还能怎样摆脱它们？ 在此处输入图片描述

答案1

清除二进制数据的最简单解决方案图标流和过去的图标流位于HKEY_CURRENT_USER\SOFTWARE\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify

  1. 运行下面的.bat 脚本
  2. 在继续操作之前，请关闭并保存您正在处理的所有内容。接下来的步骤将涉及关闭资源管理器并重新启动 PC。
  3. 运行.bat 文件。
  4. 如果出现提示，请点击/点击跑步批准。如果您愿意，您可以解除阻止 .bat 文件，以便不再收到运行（打开文件 - 安全警告）提示。
  5. 按照命令提示符中的说明重置通知区域图标。如果您现在不重新启动电脑，则需要稍后完成重置通知区域图标。（见下面的屏幕截图）

来源：如何在 Windows 10 中重置通知区域图标

重置通知区域图标缓存

:: Created by: Shawn Brink
:: http://www.tenforums.com
:: Tutorial: http://www.tenforums.com/tutorials/5662-notification-area-icons-reset-windows-10-a.html


@echo off

set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream


echo.
echo The Explorer process must be temporarily killed before deleting your notification area icons cache. 
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause


echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart

:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"


:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your notification area icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes


:no
echo.
echo.
echo Restarting explorer.... 
echo.
echo Please remember to restart the PC later to finish resetting your notification area icons.
echo.
start explorer.exe
pause
exit /B

:yes
shutdown /r /f /t 00

相关内容