☰

正确的方法与autoPatchelfHook

tag-icon • tag-icon deb nixos
正确的方法与autoPatchelfHook

考虑这个简单的 debian 包：Wolframscript.deb（要检查，您必须单击 Linux 的下载链接）。解压后，文件结构如下：

├── opt
│   └── Wolfram
│       └── WolframScript
│           └── bin
│               └── wolframscript
└── usr
    ├── local
    │   └── share
    │       └── man
    │           └── man1
    │               └── wolframscript.1
    └── share
        ├── icons
        │   └── hicolor
        │       ├── 128x128
        │       │   └── mimetypes
        │       │       └── application-vnd.wolfram.wls.png
        │       ├── 32x32
        │       │   └── mimetypes
        │       │       └── application-vnd.wolfram.wls.png
        │       └── 64x64
        │           └── mimetypes
        │               └── application-vnd.wolfram.wls.png
        └── mime
            └── packages
                └── application-vnd.wolfram.wls.xml

唯一相关的文件是opt/Wolfram/WolframScript/bin/wolframscript二进制文件（我认为）。我尝试简单地执行此操作，但出现bash: ./wolframscript: No such file or directory错误。如何使这个二进制文件/包在 NixOS 中可用？

编辑：回答@muru的问题：

$ file opt/Wolfram/WolframScript/bin/wolframscript
opt/Wolfram/WolframScript/bin/wolframscript: ELF 64-bit LSB executable, x86-64, version 1 (GNU/Linux), dynamically linked, interpreter /lib

$ ldd opt/Wolfram/WolframScript/bin/wolframscript
        linux-vdso.so.1 (0x00007fff767c9000)
        libpthread.so.0 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/libpthread.so.0 (0x00007f55b8525000)
        librt.so.1 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/librt.so.1 (0x00007f55b831d000)
        libdl.so.2 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/libdl.so.2 (0x00007f55b8119000)
        libstdc++.so.6 => not found
        libm.so.6 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/libm.so.6 (0x00007f55b7d84000)
        libgcc_s.so.1 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/libgcc_s.so.1 (0x00007f55b7b6e000)
        libc.so.6 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib/libc.so.6 (0x00007f55b77ba000)
        /lib64/ld-linux-x86-64.so.2 => /nix/store/7gx4kiv5m0i7d7qkixq2cwzbr10lvxwc-glibc-2.27/lib64/ld-linux-x86-64.so.2 (0x00007f55b874400

答案1

我介绍了这是完整的列表解决您的问题的方法，以及示例文件。当您最想要快速修复时，这两种更有效的方法是autoPatchelfHook（首选，正如 Vladimír Čunát 所建议的那样），或者最终steam-run（基于大量默认库）。buildFHSUserEnv

这是一个快速总结：

正确的方法与autoPatchelfHook

NixOs 为我们做了一个特殊的“钩子” autoPatchelfHook，可以自动为您修补所有内容！您只需在 中指定它(native)BuildInputs，然后 nix 就会发挥作用。普京derivation.nix：

{ stdenv, dpkg, glibc, gcc-unwrapped, autoPatchelfHook }:
let

  # Please keep the version x.y.0.z and do not update to x.y.76.z because the
  # source of the latter disappears much faster.
  version = "12.0.0";

  src = ./WolframScript_12.0.0_LINUX64_amd64.deb;

in stdenv.mkDerivation {
  name = "wolframscript-${version}";

  system = "x86_64-linux";

  inherit src;

  # Required for compilation
  nativeBuildInputs = [
    autoPatchelfHook # Automatically setup the loader, and do the magic
    dpkg
  ];

  # Required at running time
  buildInputs = [
    glibc
    gcc-unwrapped
  ];

  unpackPhase = "true";

  # Extract and copy executable in $out/bin
  installPhase = ''
    mkdir -p $out
    dpkg -x $src $out
    cp -av $out/opt/Wolfram/WolframScript/* $out
    rm -rf $out/opt
  '';

  meta = with stdenv.lib; {
    description = "Wolframscript";
    homepage = https://www.wolfram.com/wolframscript/;
    license = licenses.mit;
    maintainers = with stdenv.lib.maintainers; [ ];
    platforms = [ "x86_64-linux" ];
  };
}

以及default.nix：

{ pkgs ? import <nixpkgs> {} }:

pkgs.callPackage ./derivation.nix {}

编译并运行

nix-build
result/bin/wolframscript

更快的方法，与steam-run

Nix 提供了buildFHSUserEnv伪造经典 Linux 的功能。您可以直接使用它并向其中添加库，或者如果您愿意，它steam-run已经包含很多库（尽管它的名称与 steam 无关）。请注意，此方法较重并且需要较长的启动时间，因此请尽可能避免使用。

您只需要安装steam-run（您需要允许非自由软件，使用{ allowUnfree = true; }in~/.config/nixpkgs/config.nix或如果您使用nixos-rebuild，请在您的configuration.nix行中使用nixpkgs.config.allowUnfree = true;），然后运行：

steam-run ./wolframscript

更多详细信息，请参阅在 Nixos 上运行非 nixos 可执行文件的不同方法

答案2

我希望最好创建一个简单的 nix 表达式，将该 deb 作为输入，解压它等。这样您就可以“以 nix 方式”安装它（例如，依赖项不会在路径本身之前被删除）。当您这样做时，添加autoPatchelfHook到buildInputs应该可以修复这些丢失的引用。

相关内容